Control.Monad.Cont

Computation type:

Computations which can be interrupted and resumed.

Binding strategy:

Binding a function to a monadic value creates a new continuation which uses the function as the continuation of the monadic computation.

Useful for:

Complex control structures, error handling, and creating co-routines.

Zero and plus:

None.

Example type:

Cont r a

The Continuation monad represents computations in continuation-passing style (CPS). In continuation-passing style function result is not returned, but instead is passed to another function, received as a parameter (continuation). Computations are built up from sequences of nested continuations, terminated by a final continuation (often id) which produces the final result. Since continuations are functions which represent the future of a computation, manipulation of the continuation functions can achieve complex manipulations of the future of the computation, such as interrupting a computation in the middle, aborting a portion of a computation, restarting a computation, and interleaving execution of computations. The Continuation monad adapts CPS to the structure of a monad.

Before using the Continuation monad, be sure that you have a firm understanding of continuation-passing style and that continuations represent the best solution to your particular design problem. Many algorithms which require continuations in other languages do not require them in Haskell, due to Haskell's lazy semantics. Abuse of the Continuation monad can produce code that is impossible to understand and maintain.

Documentation

module Control.Monad.Cont.Class

type Cont r = ContT * r Identity

Continuation monad. Cont r a is a CPS computation that produces an intermediate result of type a within a CPS computation whose final result type is r.

The return function simply creates a continuation which passes the value on.

The >>= operator adds the bound function into the continuation chain.

mapCont :: (r -> r) -> Cont r a -> Cont r a

Apply a function to transform the result of a continuation-passing computation.

• runCont (mapCont f m) = f . runCont m

withCont :: ((b -> r) -> a -> r) -> Cont r a -> Cont r b

Apply a function to transform the continuation passed to a CPS computation.

• runCont (withCont f m) = runCont m . f

newtype ContT k (r :: k) (m :: k -> *) a :: forall k. k -> (k -> *) -> * -> *

The continuation monad transformer. Can be used to add continuation handling to any type constructor: the Monad instance and most of the operations do not require m to be a monad.

ContT is not a functor on the category of monads, and many operations cannot be lifted through it.

Constructors

ContT

Fields

• runContT :: (a -> m r) -> m r

Instances

MonadTrans (ContT * r)

Methods

lift :: Monad m => m a -> ContT * r m a

Monad (ContT k r m)

Methods

(>>=) :: ContT k r m a -> (a -> ContT k r m b) -> ContT k r m b

(>>) :: ContT k r m a -> ContT k r m b -> ContT k r m b

return :: a -> ContT k r m a

fail :: String -> ContT k r m a

Functor (ContT k r m)

Methods

fmap :: (a -> b) -> ContT k r m a -> ContT k r m b

(<$) :: a -> ContT k r m b -> ContT k r m a

MonadFail m => MonadFail (ContT * r m)

Methods

fail :: String -> ContT * r m a

Applicative (ContT k r m)

Methods

pure :: a -> ContT k r m a

(<*>) :: ContT k r m (a -> b) -> ContT k r m a -> ContT k r m b

liftA2 :: (a -> b -> c) -> ContT k r m a -> ContT k r m b -> ContT k r m c

(*>) :: ContT k r m a -> ContT k r m b -> ContT k r m b

(<*) :: ContT k r m a -> ContT k r m b -> ContT k r m a

MonadIO m => MonadIO (ContT * r m)

Methods

liftIO :: IO a -> ContT * r m a

MonadState m => MonadState (ContT * r m)

Associated Types

type StateType (ContT * r m :: * -> *) :: *

Methods

get :: ContT * r m (StateType (ContT * r m))

put :: StateType (ContT * r m) -> ContT * r m ()

MonadReader m => MonadReader (ContT * r m)

Associated Types

type EnvType (ContT * r m :: * -> *) :: *

Methods

ask :: ContT * r m (EnvType (ContT * r m))

local :: (EnvType (ContT * r m) -> EnvType (ContT * r m)) -> ContT * r m a -> ContT * r m a

Monad m => MonadCont (ContT * r m)

Methods

callCC :: ((a -> ContT * r m b) -> ContT * r m a) -> ContT * r m a

type StateType (ContT * r m)

type StateType (ContT * r m) = StateType m

type EnvType (ContT * r m)

type EnvType (ContT * r m) = EnvType m

mapContT :: (m r -> m r) -> ContT k r m a -> ContT k r m a

Apply a function to transform the result of a continuation-passing computation. This has a more restricted type than the map operations for other monad transformers, because ContT does not define a functor in the category of monads.

• runContT (mapContT f m) = f . runContT m

withContT :: ((b -> m r) -> a -> m r) -> ContT k r m a -> ContT k r m b

Apply a function to transform the continuation passed to a CPS computation.

• runContT (withContT f m) = runContT m . f

module Control.Monad

module Control.Monad.Trans

Example 1: Simple Continuation Usage

Calculating length of a list continuation-style:

calculateLength :: [a] -> Cont r Int
calculateLength l = return (length l)

Here we use calculateLength by making it to pass its result to print:

main = do
  runCont (calculateLength "123") print
  -- result: 3

It is possible to chain Cont blocks with >>=.

double :: Int -> Cont r Int
double n = return (n * 2)

main = do
  runCont (calculateLength "123" >>= double) print
  -- result: 6

Example 2: Using callCC

This example gives a taste of how escape continuations work, shows a typical pattern for their usage.

-- Returns a string depending on the length of the name parameter.
-- If the provided string is empty, returns an error.
-- Otherwise, returns a welcome message.
whatsYourName :: String -> String
whatsYourName name =
  (`runCont` id) $ do                      -- 1
    response <- callCC $ \exit -> do       -- 2
      validateName name exit               -- 3
      return $ "Welcome, " ++ name ++ "!"  -- 4
    return response                        -- 5

validateName name exit = do
  when (null name) (exit "You forgot to tell me your name!")

Here is what this example does:

1. Runs an anonymous Cont block and extracts value from it with (`runCont` id). Here id is the continuation, passed to the Cont block.
2. Binds response to the result of the following callCC block, binds exit to the continuation.
3. Validates name. This approach illustrates advantage of using callCC over return. We pass the continuation to validateName, and interrupt execution of the Cont block from inside of validateName.
4. Returns the welcome message from the callCC block. This line is not executed if validateName fails.
5. Returns from the Cont block.

Example 3: Using ContT Monad Transformer

ContT can be used to add continuation handling to other monads. Here is an example how to combine it with IO monad:

import Control.Monad.Cont
import System.IO

main = do
  hSetBuffering stdout NoBuffering
  runContT (callCC askString) reportResult

askString :: (String -> ContT () IO String) -> ContT () IO String
askString next = do
  liftIO $ putStrLn "Please enter a string"
  s <- liftIO $ getLine
  next s

reportResult :: String -> IO ()
reportResult s = do
  putStrLn ("You entered: " ++ s)

Action askString requests user to enter a string, and passes it to the continuation. askString takes as a parameter a continuation taking a string parameter, and returning IO (). Compare its signature to runContT definition.