{-
 *  Programmer:	Piotr Borek
 *  E-mail:     piotrborek@op.pl
 *  Copyright 2016 Piotr Borek
 *
 *  Distributed under the terms of the GPL (GNU Public License)
 *
 *  This program is free software; you can redistribute it and/or modify
 *  it under the terms of the GNU General Public License as published by
 *  the Free Software Foundation; either version 2 of the License, or
 *  (at your option) any later version.
 *
 *  This program is distributed in the hope that it will be useful,
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *  GNU General Public License for more details.
 *
 *  You should have received a copy of the GNU General Public License
 *  along with this program; if not, write to the Free Software
 *  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
-}
{-# LANGUAGE TemplateHaskell #-}

module Simple.UI.Widgets.Window (
    WindowType (..),
    Window,
    WindowClass,
    castToWindow,
    windowNew,
    windowType,
    windowFocus
) where

import           Control.Lens                  (makeLensesFor, (.=))
import           Simple.UI.Core.Internal.UIApp

import           Simple.UI.Core.Attribute
import           Simple.UI.Widgets.Container
import           Simple.UI.Widgets.Widget

data WindowType = WindowTypeTopLevel
                | WindowTypeDialog
                  deriving (Eq, Show)

data Window a = Window
    { _windowParent :: Container a
    , _windowType   :: WindowType
    , _windowFocus  :: Attribute Bool
    }

makeLensesFor [("_windowParent", "windowParent")] ''Window

class ContainerClass w => WindowClass w where
    castToWindow :: w a -> Window a

    windowType :: WindowClass w => w a -> WindowType
    windowType = _windowType . castToWindow

    windowFocus :: WindowClass w => w a -> Attribute Bool
    windowFocus = _windowFocus . castToWindow

instance WindowClass Window where
    castToWindow = id

instance ContainerClass Window where
    castToContainer = _windowParent

instance WidgetClass (Window a) where
    castToWidget = castToWidget . castToContainer

    overrideWidget = overrideWidgetHelper windowParent

windowNew :: LayoutClass a => WindowType -> a -> UIApp u (Window a)
windowNew = windowNewOverride

windowNewOverride :: LayoutClass a => WindowType -> a -> UIApp u (Window a)
windowNewOverride t _layout = override <$> windowNewDefault t _layout
  where
    override window = overrideWidget window $
        virtualWidgetName .= "window"

windowNewDefault :: LayoutClass a => WindowType -> a -> UIApp u (Window a)
windowNewDefault t _layout = do
    parent <- containerNew _layout
    focusLens <- attributeNew False

    return Window
        { _windowParent = parent
        , _windowType = t
        , _windowFocus = focusLens
        }