{-# LANGUAGE NoImplicitPrelude #-}
{-# LANGUAGE MultiParamTypeClasses #-}
{-# LANGUAGE FunctionalDependencies #-}
{-# LANGUAGE FlexibleContexts #-}
{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE UndecidableInstances #-}
{- |
This is like "Synthesizer.LLVM.CausalParameterized.Controlled"
but for vectorised signals.
-}
module Synthesizer.LLVM.CausalParameterized.ControlledPacked (
   C(process), processCtrlRate,
   ) where

import qualified Synthesizer.LLVM.Filter.Allpass as Allpass
import qualified Synthesizer.LLVM.Filter.FirstOrder as Filt1
import qualified Synthesizer.LLVM.Filter.SecondOrder as Filt2
import qualified Synthesizer.LLVM.Filter.SecondOrderCascade as Cascade
import qualified Synthesizer.LLVM.Filter.Moog as Moog
import qualified Synthesizer.LLVM.Filter.Universal as UniFilter

import qualified Synthesizer.LLVM.CausalParameterized.ProcessPacked as CausalPS
import qualified Synthesizer.LLVM.CausalParameterized.Process as CausalP
import qualified Synthesizer.LLVM.Parameterized.Signal as SigP
import qualified Synthesizer.LLVM.Parameter as Param
import qualified LLVM.Extra.Memory as Memory
import qualified LLVM.Extra.ScalarOrVector as SoV
import qualified LLVM.Extra.Vector as Vector
import qualified LLVM.Extra.Class as Class

import qualified LLVM.Core as LLVM
import LLVM.Core
   (Value, IsArithmetic, IsFloating, IsConst, IsSized,
    Vector, IsPrimitive, )

import qualified Data.TypeLevel.Num      as TypeNum
import qualified Data.TypeLevel.Num.Sets as TypeSet

import Foreign.Storable (Storable, )

import Control.Arrow ((<<<), first, )

import qualified Algebra.Field as Field
-- import qualified Algebra.Module as Module
-- import qualified Algebra.Ring as Ring
import qualified Algebra.Additive as Additive

import NumericPrelude.Numeric
import NumericPrelude.Base


{- |
A filter parameter type uniquely selects a filter function.
However it does not uniquely determine the input and output type,
since the same filter can run on mono and stereo signals.
-}
class C parameter a b | parameter a -> b, parameter b -> a where
   process :: CausalP.T p (parameter, a) b

processCtrlRate ::
   (C parameter av bv,
    Vector.Access n a av,
    Vector.Access n b bv,
    Memory.C parameter struct, IsSized struct ss,
    Field.C r, Storable r, IsFloating r,
    Memory.FirstClass r rm, IsSized r rs, IsSized rm rms, IsConst r,
    Class.MakeValueTuple r (Value r),
    LLVM.CmpRet r Bool) =>
   Param.T p r ->
   (Param.T p r -> SigP.T p parameter) ->
   CausalP.T p av bv
processCtrlRate reduct ctrlGen = withSize $ \n ->
   CausalP.applyFst process
      (SigP.interpolateConstant
         (fmap (/ fromIntegral (TypeNum.toInt n)) reduct)
         (ctrlGen reduct))

withSize ::
   (Vector.Access n a av,
    Vector.Access n b bv) =>
   (n -> CausalP.T p av bv) ->
   CausalP.T p av bv
withSize f = f undefined


{-
Instances for the particular filters shall be defined here
in order to avoid orphan instances.
-}

instance
   (IsArithmetic a, SoV.IntegerConstant a,
    Memory.FirstClass a am, IsSized a as, IsSized am ams,
    TypeNum.Pos n, IsPrimitive a) =>
      C (Filt1.Parameter (Value a))
        (Value (Vector n a)) (Filt1.Result (Value (Vector n a))) where
   process = Filt1.causalPackedP

instance
   (IsArithmetic a, SoV.IntegerConstant a,
    Memory.FirstClass a am, IsSized a as, IsSized am ams,
    TypeNum.Pos n, IsPrimitive a, IsPrimitive am,
    TypeNum.Mul n as vas, TypeNum.Pos vas,
    TypeNum.Mul n ams vams, TypeNum.Pos vams) =>
      C (Filt2.Parameter (Value a))
        (Value (Vector n a)) (Value (Vector n a)) where
   process = Filt2.causalPackedP

instance
   (IsArithmetic a, SoV.IntegerConstant a, IsPrimitive a, IsPrimitive am,
    Memory.FirstClass a am, IsSized a as, IsSized am ams,
    TypeSet.Nat n,
    TypeNum.Mul n LLVM.UnknownSize paramSize, TypeSet.Pos paramSize,
    TypeNum.Pos d,
    TypeNum.Mul d as vas, TypeSet.Pos vas,
    TypeNum.Mul d ams vams, TypeSet.Pos vams) =>
      C (Cascade.ParameterValue n a)
        (Value (Vector d a)) (Value (Vector d a)) where
   process = Cascade.causalPackedP


instance
   (IsArithmetic a, SoV.IntegerConstant a,
    Memory.FirstClass a am, IsSized a as, IsSized am ams,
    TypeNum.Pos n, IsPrimitive a, IsPrimitive am) =>
      C (Allpass.Parameter (Value a))
        (Value (Vector n a)) (Value (Vector n a)) where
   process = Allpass.causalPackedP

instance
   (IsArithmetic a, SoV.RationalConstant a,
    Memory.FirstClass a am, IsSized a as, IsSized am ams,
    TypeNum.Pos d, IsPrimitive a,
    TypeNum.Nat n) =>
      C (Allpass.CascadeParameter n (Value a))
        (Value (Vector d a)) (Value (Vector d a)) where
   process = Allpass.cascadePackedP


instance
   (SoV.PseudoModule a a, SoV.IntegerConstant a, Additive.C a,
    Memory.FirstClass a am, IsSized a as, IsSized am ams,
    Class.MakeValueTuple a (Value a), Storable a,
    TypeNum.Pos d, IsPrimitive a,
    TypeNum.Nat n) =>
      C (Moog.Parameter n (Value a))
        (Value (Vector d a)) (Value (Vector d a)) where
   process =
      CausalPS.pack Moog.causalP <<<
      first (CausalP.mapSimple Vector.replicate)


instance
   (SoV.PseudoModule a a, SoV.RationalConstant a,
    Memory.FirstClass a am, IsSized a as, IsSized am ams,
    TypeNum.Pos d, IsPrimitive a) =>
      C (UniFilter.Parameter (Value a))
        (Value (Vector d a)) (UniFilter.Result (Value (Vector d a))) where
   process =
      CausalPS.pack UniFilter.causalP <<<
      first (CausalP.mapSimple Vector.replicate)