/* -----------------------------------------------------------------------------
Copyright 2019-2021 Kevin P. Barry

Licensed under the Apache License, Version 2.0 (the "License");
you may not use this file except in compliance with the License.
You may obtain a copy of the License at

    http://www.apache.org/licenses/LICENSE-2.0

Unless required by applicable law or agreed to in writing, software
distributed under the License is distributed on an "AS IS" BASIS,
WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
See the License for the specific language governing permissions and
limitations under the License.
----------------------------------------------------------------------------- */

// Author: Kevin P. Barry [ta0kira@gmail.com]

testcase "TypeMap tests" {
  success
}

unittest basicOperations {
  TypeMap tree <- TypeMap.new()

  TypeKey<Int>    keyInt    <- TypeKey<Int>.new()
  TypeKey<String> keyString <- TypeKey<String>.new()
  TypeKey<Value>  keyValue  <- TypeKey<Value>.new()

  \ Testing.checkOptional<?>(tree.get<?>(keyInt),   empty)
  \ Testing.checkOptional<?>(tree.get<?>(keyString),empty)
  \ Testing.checkOptional<?>(tree.get<?>(keyValue), empty)

  \ tree.set<?>(keyInt,1)
  \ tree.set<?>(keyString,"a")
  \ tree.set<?>(keyValue,Value.new())

  \ Testing.checkOptional<?>(tree.get<?>(keyInt),   1)
  \ Testing.checkOptional<?>(tree.get<?>(keyString),"a")
  \ Testing.checkOptional<?>(tree.get<?>(keyValue), Value.new())

  \ tree.remove(keyString)

  \ Testing.checkOptional<?>(tree.get<?>(keyString),empty)
}

unittest wrongReturnType {
  TypeMap tree <- TypeMap.new()

  TypeKey<String> keyString <- TypeKey<String>.new()

  // Added as Formatted, which means it cannot be retrieved as String later.
  \ tree.set<Formatted>(keyString,"a")
  \ Testing.checkOptional<?>(tree.get<String>(keyString),empty)

  \ tree.set<String>(keyString,"a")
  \ Testing.checkOptional<?>(tree.get<String>(keyString),"a")
}

concrete Value {
  refines Formatted
  defines Equals<Value>

  @type new () -> (Value)
}

define Value {
  new () {
    return Value{ }
  }

  formatted () {
    return "Value"
  }

  equals (_,_) {
    return true
  }
}