Ticket #4336: benchRecip.hs

module Main (main) where

import System.CPUTime
import System.Environment (getArgs)
import Text.Printf
import GHC.Real
import Data.Word
import Data.Int

frecip :: Integral a => Ratio a -> Ratio a
frecip (0 :% _) = error "zero denominator"
frecip (x :% y)
    | x < 0     = negate y :% negate x
    | otherwise = y :% x

makeSmall :: Integral a => Ratio a -> a
makeSmall (x :% y) = x `mod` 121 + y `mod` 97

fibs :: Integral a => [a]
fibs = 1 : 1 : go fibs (tail fibs)
  where
    go (x:xs) (y:ys) = x + y : go xs ys

fibQuots :: Integral a => [Ratio a]
fibQuots = go fibs
  where
    go (x:(xs@(y:_))) = x :% y : go xs

result :: Integral a => Int -> (Ratio a -> Ratio a) -> a
result k fun = sum . map (makeSmall . fun) $ take k fibQuots

test :: Integral a => a -> Int -> IO ()
test v k = do
    u0 <- getCPUTime
    print $ v + result k id
    u1 <- getCPUTime
    printf "id took %.6fs\n" (fromInteger (u1-u0) * (1e-12 :: Double)) :: IO ()
    t0 <- getCPUTime
    print $ v + result k frecip
    t1 <- getCPUTime
    printf "frecip took %.6fs\n" (fromInteger (t1-t0) * (1e-12 :: Double)) :: IO ()
    t2 <- getCPUTime
    print $ v + result k recip
    t3 <- getCPUTime
    printf "recip took %.6fs\n" (fromInteger (t3-t2) * (1e-12 :: Double))

main :: IO ()
main = do
  args <- getArgs
  let (k,t) = case args of
                (a:b:_) -> (read a, read b)
                (a:_)   -> (read a, 0)
                _       -> (5000, 0)
  case t of
    0 -> test (0 :: Integer) k
    1 -> test (0 :: Int) k
    2 -> test (0 :: Int64) k
    3 -> test (0 :: Word) k
    4 -> test (0 :: Word64) k