Ticket #4344: logarithms-integer-simple.dpatch

1 patch for repository /home/dafis/Haskell/Hacking/ghc/libraries/integer-simple:

Mon Oct 25 21:56:27 CEST 2010  Daniel Fischer <daniel.is.fischer@web.de>
  * Logarithms for integer-simple
  Integer logarithms as needed for fromRational.
  So far, they have not been optimised at all.

New patches:

[Logarithms for integer-simple
Daniel Fischer <daniel.is.fischer@web.de>**20101025195627
 Ignore-this: f720182ed430fcc6788e3296ea250e3c
 Integer logarithms as needed for fromRational.
 So far, they have not been optimised at all.
] {
adddir ./GHC/Integer/Logarithms
addfile ./GHC/Integer/Logarithms.hs
hunk ./GHC/Integer/Logarithms.hs 1
+{-# LANGUAGE MagicHash, UnboxedTuples, NoImplicitPrelude #-}
+module GHC.Integer.Logarithms
+    ( integerLogBase#
+    , integerLog2#
+    , wordLog2#
+    ) where
+
+import GHC.Prim
+import GHC.Integer
+import qualified GHC.Integer.Logarithms.Internals as I
+
+-- | Calculate the integer logarithm for an arbitrary base.
+--   The base must be greater than 1, the second argument, the number
+--   whose logarithm is sought, should be positive, otherwise the
+--   result is meaningless.
+--
+-- >
+--   base ^ integerLogBase# base m <= m < base ^ (integerLogBase# base m + 1)
+-- >
+--
+-- for @base > 1@ and @m > 0@.
+integerLogBase# :: Integer -> Integer -> Int#
+integerLogBase# b m = case step b of
+                        (# _, e #) -> e
+  where
+    step pw =
+      if m `ltInteger` pw
+        then (# m, 0# #)
+        else case step (pw `timesInteger` pw) of
+               (# q, e #) ->
+                 if q `ltInteger` pw
+                   then (# q, 2# *# e #)
+                   else (# q `quotInteger` pw, 2# *# e +# 1# #)
+
+-- | Calculate the integer base 2 logarithm of an 'Integer'.
+--   The calculation should be more efficient than for the general case.
+--
+--  The argument must be strictly positive, that condition is /not/ checked.
+integerLog2# :: Integer -> Int#
+integerLog2# = I.integerLog2#
+
+-- | This function calculates the integer base 2 logarithm of a 'Word#'.
+wordLog2# :: Word# -> Int#
+wordLog2# = I.wordLog2#
addfile ./GHC/Integer/Logarithms/Internals.hs
hunk ./GHC/Integer/Logarithms/Internals.hs 1
+{-# LANGUAGE CPP, MagicHash, UnboxedTuples, NoImplicitPrelude #-}
+{-# OPTIONS_HADDOCK hide #-}
+
+#include "MachDeps.h"
+
+module GHC.Integer.Logarithms.Internals
+    ( integerLog2#
+    , integerLog2IsPowerOf2#
+    , wordLog2#
+    , roundingMode#
+    ) where
+
+import GHC.Prim
+import GHC.Integer.Type
+import GHC.Integer
+
+default ()
+
+-- When larger word sizes become common, add support for those,
+-- it is not hard, just tedious.
+#if (WORD_SIZE_IN_BITS != 32) && (WORD_SIZE_IN_BITS != 64)
+
+-- We do not know whether the word has 30 bits or 128 or even more,
+-- so we cannot start from the top, although that would be much more
+-- efficient.
+wordLog2# :: Word# -> Int#
+wordLog2# w = go 8# w
+  where
+    go acc u = case u `uncheckedShiftRL#` 8# of
+                0## -> case leadingZeros of
+                        BA ba -> acc -# indexInt8Array# ba (word2Int# u)
+                v   -> go (acc +# 8#) v
+
+#else
+
+-- This one at least can also be done efficiently.
+-- wordLog2# 0## = -1#
+{-# INLINE wordLog2# #-}
+wordLog2# :: Word# -> Int#
+wordLog2# w =
+  case leadingZeros of
+   BA lz ->
+    let zeros u = indexInt8Array# lz (word2Int# u) in
+#if WORD_SIZE_IN_BITS == 64
+    case uncheckedShiftRL# w 56# of
+     a ->
+      if a `neWord#` 0##
+       then 64# -# zeros a
+       else
+        case uncheckedShiftRL# w 48# of
+         b ->
+          if b `neWord#` 0##
+           then 56# -# zeros b
+           else
+            case uncheckedShiftRL# w 40# of
+             c ->
+              if c `neWord#` 0##
+               then 48# -# zeros c
+               else
+                case uncheckedShiftRL# w 32# of
+                 d ->
+                  if d `neWord#` 0##
+                   then 40# -# zeros d
+                   else
+#endif
+                    case uncheckedShiftRL# w 24# of
+                     e ->
+                      if e `neWord#` 0##
+                       then 32# -# zeros e
+                       else
+                        case uncheckedShiftRL# w 16# of
+                         f ->
+                          if f `neWord#` 0##
+                           then 24# -# zeros f
+                           else
+                            case uncheckedShiftRL# w 8# of
+                             g ->
+                              if g `neWord#` 0##
+                               then 16# -# zeros g
+                               else  8# -# zeros w
+
+#endif
+
+-- As for the rest, I will see later what efficiency we can gain.
+
+-- Assumption: Integer is strictly positive
+integerLog2# :: Integer -> Int#
+integerLog2# m = case step m (smallInteger 2#) 1# of
+                    (# _, l #) -> l
+  where
+    -- Invariants:
+    -- pw = 2 ^ lg
+    -- case step n pw lg of
+    --   (q, e) -> pw^(2*e) <= n < pw^(2*e+2)
+    --              && q <= n/pw^(2*e) < (q+1)
+    --              && q < pw^2
+    step n pw lg =
+      if n `ltInteger` pw
+        then (# n, 0# #)
+        else case step n (shiftLInteger pw lg) (2# *# lg) of
+              (# q, e #) ->
+                if q `ltInteger` pw
+                  then (# q, 2# *# e #)
+                  else (# q `shiftRInteger` lg, 2# *# e +# 1# #)
+
+integerLog2IsPowerOf2# :: Integer -> (# Int#, Int# #)
+integerLog2IsPowerOf2# m =
+    case integerLog2# m of
+      lg -> if m `eqInteger` (smallInteger 1# `shiftLInteger` lg)
+              then (# lg, 0# #)
+              else (# lg, 1# #)
+
+roundingMode# :: Integer -> Int# -> Int#
+roundingMode# m h =
+    case smallInteger 1# `shiftLInteger` h of
+      c -> case m `andInteger`
+                ((c `plusInteger` c) `minusInteger` smallInteger 1#) of
+             r ->
+               if c `ltInteger` r
+                 then 2#
+                 else if c `gtInteger` r
+                        then 0#
+                        else 1#
+
+-- Lookup table
+data BA = BA ByteArray#
+
+leadingZeros :: BA
+leadingZeros =
+    let mkArr s =
+          case newByteArray# 256# s of
+            (# s1, mba #) ->
+              case writeInt8Array# mba 0# 9# s1 of
+                s2 ->
+                  let fillA lim val idx st =
+                        if idx ==# 256#
+                          then st
+                          else if idx <# lim
+                                then case writeInt8Array# mba idx val st of
+                                        nx -> fillA lim val (idx +# 1#) nx
+                                else fillA (2# *# lim) (val -# 1#) idx st
+                  in case fillA 2# 8# 1# s2 of
+                      s3 -> case unsafeFreezeByteArray# mba s3 of
+                              (# _, ba #) -> ba
+    in case mkArr realWorld# of
+        b -> BA b
hunk ./integer-simple.cabal 16
     build-depends: ghc-prim
     exposed-modules: GHC.Integer
                      GHC.Integer.Simple.Internals
+                     GHC.Integer.Logarithms
+                     GHC.Integer.Logarithms.Internals
     other-modules: GHC.Integer.Type
     extensions: CPP, MagicHash, BangPatterns, UnboxedTuples,
                 ForeignFunctionInterface, UnliftedFFITypes,
}

Context:

[Follow GHC.Bool/GHC.Types merge
Ian Lynagh <igloo@earth.li>**20101023153842
 Ignore-this: eb0bf266cd02a9a11edd84bb0db02b92
] 
[Pad version to 0.1.0.0
Ian Lynagh <igloo@earth.li>**20090920141930] 
[Add NoImplicitPrelude to the extensions used
Ian Lynagh <igloo@earth.li>**20090722174729] 
[Add an import so the deps get sorted out correctly
Ian Lynagh <igloo@earth.li>**20090722162843] 
[() is now available, so use that instead of our own
Ian Lynagh <igloo@earth.li>**20090722161829] 
[Follow changes in GHC and the other libraries
Ian Lynagh <igloo@earth.li>**20090722131507] 
[Fix conversions between Float/Double and simple-integer
Ian Lynagh <igloo@earth.li>**20080614152452] 
[Sprinkle on some strictness annotations
Ian Lynagh <igloo@earth.li>**20080602193146] 
[Make the Integer type components strict
Ian Lynagh <igloo@earth.li>**20080602185149] 
[Avoid the need for infinite Integers when doing bitwise operations
Ian Lynagh <igloo@earth.li>**20080602184237] 
[Initial commit
Ian Lynagh <igloo@earth.li>**20080425024824] 
Patch bundle hash:
b0abc0640f6fa306df1d127dbed7917198b4eab7