-- | The CIDR modules contains most of the functions used for working
--   with the CIDR type.
module Cidr
( Cidr(..),
  cidr_properties,
  cidr_tests,
  combine_all,
  contains,
  contains_proper,
  enumerate,
  max_octet1,
  max_octet2,
  max_octet3,
  max_octet4,
  min_octet1,
  min_octet2,
  min_octet3,
  min_octet4,
  prop_all_cidrs_contain_themselves,
  prop_contains_proper_intransitive
) where

import Data.List (nubBy)
import Data.List.Split (splitOneOf)
import Data.Maybe (catMaybes, mapMaybe)

import Test.HUnit (assertEqual)
import Test.Framework (Test, testGroup)
import Test.Framework.Providers.HUnit (testCase)
import Test.Framework.Providers.QuickCheck2 (testProperty)
import Test.QuickCheck (Arbitrary(..), Gen, Property, (==>))
import Text.Read (readMaybe)

import qualified Bit as B (Bit(..))
import IPv4Address (IPv4Address(..), most_sig_bit_different)
import Maskable (Maskable(..))
import Maskbits (Maskbits(..))
import Octet (Octet(..))


data Cidr = Cidr { ipv4address :: IPv4Address,
                   maskbits :: Maskbits }


instance Show Cidr where
    show cidr = (show (ipv4address cidr)) ++ "/" ++ (show (maskbits cidr))


instance Arbitrary Cidr where
    arbitrary = do
      ipv4 <- arbitrary :: Gen IPv4Address
      mask <- arbitrary :: Gen Maskbits
      return (Cidr ipv4 mask)


instance Eq Cidr where
  cidr1 == cidr2 = (cidr1 `equivalent` cidr2)


-- | Two CIDR ranges are equivalent if they have the same network bits
--   and the masks are the same.
equivalent :: Cidr -> Cidr -> Bool
equivalent (Cidr addr1 mbits1) (Cidr addr2 mbits2) =
    (mbits1 == mbits2) && ((apply_mask addr1 mbits1 B.Zero) == (apply_mask addr2 mbits2 B.Zero))

-- | Returns the mask portion of a CIDR address. That is, everything
--   after the trailing slash.
maskbits_from_cidr_string :: String -> Maybe Maskbits
maskbits_from_cidr_string s
  | length partlist == 2 = readMaybe (partlist !! 1)
  | otherwise = Nothing
    where
      partlist = splitOneOf "/" s


-- | Takes an IP address String in CIDR notation, and returns a list
--   of its octets (as Ints).
octets_from_cidr_string :: String -> [Octet]
octets_from_cidr_string s =
  case parts of
    (p1:p2:p3:p4:_) -> mapMaybe readMaybe [p1,p2,p3,p4]
    _ -> []
  where
    parts = splitOneOf "./" s

instance Read Cidr where
  -- | Parse everything or nothing.
  readsPrec _ s =
    case (octets_from_cidr_string s) of
      [oct1, oct2, oct3, oct4] ->
        case (maskbits_from_cidr_string s) of
          Just mbits ->
            [(Cidr (IPv4Address oct1 oct2 oct3 oct4) mbits, "")]
          _ -> []
      _ -> []


-- | Given a CIDR, return the minimum valid IPv4 address contained
--   within it.
min_host :: Cidr -> IPv4Address
min_host (Cidr addr mask) = apply_mask addr mask B.Zero

-- | Given a CIDR, return the maximum valid IPv4 address contained
--   within it.
max_host :: Cidr -> IPv4Address
max_host (Cidr addr mask) = apply_mask addr mask B.One

-- | Given a CIDR, return the first octet of the minimum valid IPv4
--   address contained within it.
min_octet1 :: Cidr -> Octet
min_octet1 cidr = octet1 (min_host cidr)

-- | Given a CIDR, return the second octet of the minimum valid IPv4
--   address contained within it.
min_octet2 :: Cidr -> Octet
min_octet2 cidr = octet2 (min_host cidr)

-- | Given a CIDR, return the third octet of the minimum valid IPv4
--   address contained within it.
min_octet3 :: Cidr -> Octet
min_octet3 cidr = octet3 (min_host cidr)

-- | Given a CIDR, return the fourth octet of the minimum valid IPv4
--   address contained within it.
min_octet4 :: Cidr -> Octet
min_octet4 cidr = octet4 (min_host cidr)

-- | Given a CIDR, return the first octet of the maximum valid IPv4
--   address contained within it.
max_octet1 :: Cidr -> Octet
max_octet1 cidr = octet1 (max_host cidr)

-- | Given a CIDR, return the second octet of the maximum valid IPv4
--   address contained within it.
max_octet2 :: Cidr -> Octet
max_octet2 cidr = octet2 (max_host cidr)

-- | Given a CIDR, return the third octet of the maximum valid IPv4
--   address contained within it.
max_octet3 :: Cidr -> Octet
max_octet3 cidr = octet3 (max_host cidr)

-- | Given a CIDR, return the fourth octet of the maximum valid IPv4
--   address contained within it.
max_octet4 :: Cidr -> Octet
max_octet4 cidr = octet4 (max_host cidr)



-- | Return true if the first argument (a CIDR range) contains the
--   second (another CIDR range). There are a lot of ways we can be
--   fed junk here. For lack of a better alternative, just return
--   False when we are given nonsense.
--
--   If the number of bits in the network part of the first address is
--   larger than the number of bits in the second, there is no way
--   that the first range can contain the second. For, if the number
--   of network bits is larger, then the number of host bits must be
--   smaller, and if cidr1 has fewer hosts than cidr2, cidr1 most
--   certainly does not contain cidr2.
--
--   On the other hand, if the first argument (cidr1) has fewer (or
--   the same number of) network bits as the second, it can contain
--   the second. In this case, we need to check that every host in
--   cidr2 is contained in cidr1. If a host in cidr2 is contained in
--   cidr1, then at least mbits1 of an address in cidr2 will match
--   cidr1. For example,
--
--   cidr1 = 192.168.1.0\/23, cidr2 = 192.168.1.100\/24
--
--   Here, cidr2 contains all of 192.168.1.0 through
--   192.168.1.255. However, cidr1 contains BOTH 192.168.0.0 through
--   192.168.0.255 and 192.168.1.0 through 192.168.1.255. In essence,
--   what we want to check is that cidr2 "begins with" something that
--   cidr1 CAN begin with. Since cidr1 can begin with 192.168.1, and
--   cidr2 DOES, cidr1 contains cidr2..
--
--   The way that we check this is to apply cidr1's mask to cidr2's
--   address and see if the result is the same as cidr1's mask applied
--   to cidr1's address.
--
contains :: Cidr -> Cidr -> Bool
contains (Cidr addr1 mbits1) (Cidr addr2 mbits2)
  | mbits1 > mbits2 = False
  | otherwise = addr1masked == addr2masked
  where
    addr1masked = apply_mask addr1 mbits1 B.Zero
    addr2masked = apply_mask addr2 mbits1 B.Zero


-- | Contains but is not equal to.
contains_proper :: Cidr -> Cidr -> Bool
contains_proper cidr1 cidr2 =
    (cidr1 `contains` cidr2) && (not (cidr2 `contains` cidr1))


-- | A CIDR range is redundant (with respect to the given list) if
--   another CIDR range in that list properly contains it.
redundant :: [Cidr] -> Cidr -> Bool
redundant cidrlist cidr = any ((flip contains_proper) cidr) cidrlist


-- | First, we look at all possible pairs of cidrs, and combine the
--   adjacent ones in to a new list. Then, we concatenate that list
--   with the original one, and filter out all of the redundancies. If
--   two adjacent Cidrs are combined into a larger one, they will be
--   removed in the second step since the larger Cidr must contain the
--   smaller two.
--
--   Once this is done, we see whether or not the result is different
--   than the argument that was passed in. If nothing changed, we're
--   done and return the list that was passed to us. However, if
--   something changed, we recurse and try to combine the list again.
combine_all :: [Cidr] -> [Cidr]
combine_all cidrs
  | cidrs == (combine_contained unique_cidrs) = cidrs
  | otherwise = combine_all (combine_contained unique_cidrs)
    where
      unique_cidrs = nubBy equivalent cidr_combinations
      cidr_combinations =
        cidrs ++ (catMaybes [ (combine_adjacent x y) | x <- cidrs, y <- cidrs ])


-- | Take a list of CIDR ranges and filter out all of the ones that
--   are contained entirelt within some other range in the list.
combine_contained :: [Cidr] -> [Cidr]
combine_contained cidrs =
  filter (not . (redundant cidrs)) cidrs


-- | If the two Cidrs are not adjacent, return Cidr.None. Otherwise,
--   decrement the maskbits of cidr1 and return that; it will contain
--   both cidr1 and cidr2.
combine_adjacent :: Cidr -> Cidr -> Maybe Cidr
combine_adjacent cidr1 cidr2
  | not (adjacent cidr1 cidr2) = Nothing
  | (maskbits cidr1 == Zero) = Nothing
  | otherwise = Just $ cidr1 { maskbits = pred (maskbits cidr1) }



-- | Determine whether or not two CIDR ranges are adjacent. If two
--   ranges lie consecutively within the IP space, they can be
--   combined. For example, 10.1.0.0/24 and 10.0.1.0/24 are adjacent,
--   and can be combined in to 10.1.0.0/23.
adjacent :: Cidr -> Cidr -> Bool
adjacent cidr1 cidr2
  | mbits1 /= mbits2 = False
  | mbits1 == Maskbits.Zero = False -- They're equal.
  | otherwise = (mbits1 == (most_sig_bit_different addr1 addr2))
  where
    addr1 = ipv4address cidr1
    addr2 = ipv4address cidr2
    mbits1 = maskbits cidr1
    mbits2 = maskbits cidr2


enumerate :: Cidr -> [IPv4Address]
enumerate cidr = [(min_host cidr)..(max_host cidr)]

-- Test lists.
cidr_tests :: Test
cidr_tests =
  testGroup "CIDR Tests" [
    test_enumerate,
    test_min_host1,
    test_max_host1,
    test_equality1,
    test_contains1,
    test_contains2,
    test_contains_proper1,
    test_contains_proper2,
    test_adjacent1,
    test_adjacent2,
    test_adjacent3,
    test_adjacent4,
    test_combine_contained1,
    test_combine_contained2,
    test_combine_all1,
    test_combine_all2,
    test_combine_all3 ]

cidr_properties :: Test
cidr_properties =
  testGroup "CIDR Properties" [
    testProperty
      "All CIDRs contain themselves"
      prop_all_cidrs_contain_themselves,

    testProperty
      "contains_proper is intransitive"
      prop_contains_proper_intransitive
  ]


-- HUnit Tests
test_enumerate :: Test
test_enumerate =
  testCase desc $ assertEqual desc expected actual
  where
    desc = "192.168.0.240/30 is enumerated correctly"
    oct1 = toEnum 192
    oct2 = toEnum 168
    oct3 = minBound
    mk_ip = IPv4Address oct1 oct2 oct3
    addr1 = mk_ip $ toEnum 240
    addr2 = mk_ip $ toEnum 241
    addr3 = mk_ip $ toEnum 242
    addr4 = mk_ip $ toEnum 243
    expected = [addr1, addr2, addr3, addr4]
    actual = enumerate $ read "192.168.0.240/30"

test_min_host1 :: Test
test_min_host1 =
  testCase desc $
    assertEqual desc
    expected
    actual
  where
    desc = "The minimum host in 10.0.0.0/24 is 10.0.0.0"
    actual = show $ min_host (read "10.0.0.0/24")
    expected = "10.0.0.0"


test_max_host1 :: Test
test_max_host1 =
  testCase desc $
    assertEqual desc
    expected
    actual
  where
    desc = "The maximum host in 10.0.0.0/24 is 10.0.0.255"
    actual = show $ max_host (read "10.0.0.0/24")
    expected = "10.0.0.255"


test_equality1 :: Test
test_equality1 =
  testCase desc $
    assertEqual
    desc
    True
    (cidr1 == cidr1)
  where
    desc = "10.1.1.0/23 equals itself"
    cidr1 = read "10.1.1.0/23" :: Cidr


test_contains1 :: Test
test_contains1 =
  testCase desc $
    assertEqual
    desc
    True
    (cidr1 `contains` cidr2)
  where
    desc = "10.1.1.0/23 contains 10.1.1.0/24"
    cidr1 = read "10.1.1.0/23"
    cidr2 = read "10.1.1.0/24"


test_contains2 :: Test
test_contains2 =
  testCase desc $
    assertEqual
    desc
    True
    (cidr1 `contains` cidr1)
  where
    desc = "10.1.1.0/23 contains itself"
    cidr1 = read "10.1.1.0/23"


test_contains_proper1 :: Test
test_contains_proper1 =
  testCase desc $
    assertEqual
    desc
    True
    (cidr1 `contains_proper` cidr2)
  where
    desc = "10.1.1.0/23 contains 10.1.1.0/24 properly"
    cidr1 = read "10.1.1.0/23"
    cidr2 = read "10.1.1.0/24"


test_contains_proper2 :: Test
test_contains_proper2 =
  testCase desc $
    assertEqual
    desc
    False
    (cidr1 `contains_proper` cidr1)
  where
    desc = "10.1.1.0/23 does not contain itself properly"
    cidr1 = read "10.1.1.0/23"


test_adjacent1 :: Test
test_adjacent1 =
  testCase desc $
    assertEqual
    desc
    True
    (cidr1 `adjacent` cidr2)
  where
    desc = "10.1.0.0/24 is adjacent to 10.1.1.0/24"
    cidr1 = read "10.1.0.0/24"
    cidr2 = read "10.1.1.0/24"


test_adjacent2 :: Test
test_adjacent2 =
  testCase desc $
    assertEqual
    desc
    False
    (cidr1 `adjacent` cidr2)
  where
    desc = "10.1.0.0/23 is not adjacent to 10.1.0.0/24"
    cidr1 = read "10.1.0.0/23"
    cidr2 = read "10.1.0.0/24"


test_adjacent3 :: Test
test_adjacent3 =
  testCase desc $
    assertEqual
    desc
    False
    (cidr1 `adjacent` cidr2)
  where
    desc = "10.1.0.0/24 is not adjacent to 10.2.5.0/24"
    cidr1 = read "10.1.0.0/24"
    cidr2 = read "10.2.5.0/24"


test_adjacent4 :: Test
test_adjacent4 =
  testCase desc $
    assertEqual
    desc
    False
    (cidr1 `adjacent` cidr2)
  where
    desc = "10.1.1.0/24 is not adjacent to 10.1.2.0/24"
    cidr1 = read "10.1.1.0/24"
    cidr2 = read "10.1.2.0/24"


test_combine_contained1 :: Test
test_combine_contained1 =
  testCase desc $
    assertEqual
    desc
    expected_cidrs
    (combine_contained test_cidrs)
  where
    desc = "10.0.0.0/8, 10.1.0.0/16, and 10.1.1.0/24 combine to 10.0.0.0/8"
    cidr1 = read "10.0.0.0/8"
    cidr2 = read "10.1.0.0/16"
    cidr3 = read "10.1.1.0/24"
    expected_cidrs = [cidr1]
    test_cidrs = [cidr1, cidr2, cidr3]


test_combine_contained2 :: Test
test_combine_contained2 =
  testCase desc $
    assertEqual
    desc
    [cidr1, cidr2]
    (combine_contained [cidr1, cidr2])
  where
    desc = "192.168.3.0/23 does not contain 192.168.1.0/24"
    cidr1 = read "192.168.3.0/23"
    cidr2 = read "192.168.1.0/24"


test_combine_all1 :: Test
test_combine_all1 =
  testCase desc $
    assertEqual
    desc
    expected_cidrs
    (combine_all test_cidrs)
  where
    desc = "10.0.0.0/24 is adjacent to 10.0.1.0/24 "
           ++ "and 10.0.3.0/23 contains 10.0.2.0/24"
    cidr1 = read "10.0.0.0/24"
    cidr2 = read "10.0.1.0/24"
    cidr3 = read "10.0.2.0/24"
    cidr4 = read "10.0.3.0/23"
    cidr5 = read "10.0.0.0/23"
    expected_cidrs = [read "10.0.0.0/22"]
    test_cidrs = [cidr1, cidr2, cidr3, cidr4, cidr5]


test_combine_all2 :: Test
test_combine_all2 =
    testCase desc $
      assertEqual
      desc
      expected_cidrs
      (combine_all test_cidrs)
    where
      desc = "127.0.0.1/32 combines with itself recursively"
      cidr1 = read "127.0.0.1/32"
      expected_cidrs = [cidr1]
      test_cidrs = [cidr1, cidr1, cidr1, cidr1, cidr1]


test_combine_all3 :: Test
test_combine_all3 =
  testCase desc $
    assertEqual
    desc
    expected_cidrs
    (combine_all test_cidrs)
  where
    desc = "10.0.0.16, 10.0.0.17, 10.0.0.18, and "
           ++ "10.0.0.19 get combined into 10.0.0.16/30"
    cidr1 = read "10.0.0.16/32"
    cidr2 = read "10.0.0.17/32"
    cidr3 = read "10.0.0.18/32"
    cidr4 = read "10.0.0.19/32"
    expected_cidrs = [read "10.0.0.16/30"]
    test_cidrs = [cidr1, cidr2, cidr3, cidr4]


-- QuickCheck Tests
prop_all_cidrs_contain_themselves :: Cidr -> Bool
prop_all_cidrs_contain_themselves cidr1 = cidr1 `contains` cidr1


-- If cidr1 properly contains cidr2, then by definition cidr2
-- does not properly contain cidr1.
prop_contains_proper_intransitive :: Cidr -> Cidr -> Property
prop_contains_proper_intransitive cidr1 cidr2 =
    (cidr1 `contains_proper` cidr2) ==>
      (not (cidr2 `contains_proper` cidr1))