-- | Functions for comparing 'Double' values.
module Comparisons (
  (~=),
  (~~=),
  almost_equals,
  kinda_equals,
  nearly_equals,
  nearly_ge,
  non_very_positive_entries,
  very_positive )
where


-- | epsilon is the value that will be used in all tests that require
--   some measure of \"closeness.\" Increasing it will make those
--   tests more tolerant.
  --
epsilon :: Double
epsilon = 0.0001


-- | A tiny margin of error.
--
theta :: Double
theta = 0.0000000000001


-- | x almost equals y if x is within 'theta' of y.
--
--   Only used in tests.
--
nearly_equals :: Double -> Double -> Bool
nearly_equals x y =
  (abs (x - y)) < theta


-- | Nearly greater-than or equal-to.
--
--   Only used in tests.
--
nearly_ge :: Double -> Double -> Bool
x `nearly_ge` y =
  (x > y) || (x `nearly_equals` y)


-- | x almost equals y if x is within 'epsilon' of y.
--
--   Only used in tests.
--
almost_equals :: Double -> Double -> Bool
almost_equals x y =
  (abs (x - y)) < epsilon

infix 4 ~=
(~=) :: Double -> Double -> Bool
(~=) = almost_equals


-- | Like 'almost_equals', except much more tolerant. The difference
--   between the two arguments must be less than one percent of the sum
--   of their magnitudes.
--
--   Only used in tests.
--
kinda_equals :: Double -> Double -> Bool
kinda_equals x y =
  (abs (x - y)) < threshold
  where
    threshold = ((abs x) + (abs y)) / 100.0

infix 4 ~~=
(~~=) :: Double -> Double -> Bool
(~~=) = kinda_equals


-- | x is very positive if it is 'epsilon' greater than zero.
--
--   Only used in tests.
--
very_positive :: Double -> Bool
very_positive x =
  x - epsilon > 0


-- | Takes a list of 'Double' and returns the ones which are not very
--   positive.
--
non_very_positive_entries :: [Double] -> [Double]
non_very_positive_entries = filter (not . very_positive)