Network.HTTP2.Server

HTTP/2 server library.

Example:

{-# LANGUAGE OverloadedStrings #-}
module Main (main) where

import Control.Concurrent (forkFinally)
import qualified Control.Exception as E
import Control.Monad (forever, void)
import Data.ByteString.Builder (byteString)
import Network.HTTP.Types (ok200)
import Network.HTTP2.Server
import Network.Socket

main :: IO ()
main = withSocketsDo $ do
    addr <- resolve "80"
    E.bracket (open addr) close loop
  where
    server _req _ctl sendResponse = sendResponse response []
      where
        response = responseBuilder ok200 [("Content-Type", "text/plain")] (byteString "Hello, world!\n")
    loop sock = forever $ do
        (s, _peer) <- accept sock
        (config, cleanup) <- makeSimpleConfig s 4096
        void $ forkFinally (run config server) (\_ -> close s >> cleanup)
    resolve port = do
        let hints = defaultHints {
                addrFlags = [AI_PASSIVE]
              , addrSocketType = Stream
              }
        addr:_ <- getAddrInfo (Just hints) Nothing (Just port)
        return addr
    open addr = do
        sock <- socket (addrFamily addr) (addrSocketType addr) (addrProtocol addr)
        setSocketOption sock ReuseAddr 1
        withFdSocket sock $ setCloseOnExecIfNeeded
        bind sock (addrAddress addr)
        listen sock 10
        return sock

Runner

run :: Config -> Server -> IO ()

Running HTTP/2 server.

Runner arguments

data Config

HTTP/2 server configuration.

Constructors

Config

Fields

• confWriteBuffer :: Buffer
• confBufferSize :: BufferSize
• confSendAll :: ByteString -> IO ()
• confReadN :: Int -> IO ByteString
• confPositionReadMaker :: PositionReadMaker

makeSimpleConfig :: Socket -> BufferSize -> IO (Config, IO ())

Making configuration whose IO is not efficient. A write buffer is allocated internally. That should be deallocated by the returned action.

HTTP/2 server

type Server = Request -> Aux -> (Response -> [PushPromise] -> IO ()) -> IO ()

HTTP/2 server takes a HTTP request, should generate a HTTP response and push promises, then should give them to the sending function. The sending function would throw exceptions so that they can be logged.

Request

data Request

HTTP request.

requestHeaders :: Request -> HeaderTable

Accessor for request headers.

requestBodySize :: Request -> Maybe Int

Accessor for body length specified in content-length:.

getRequestBodyChunk :: Request -> IO ByteString

Reading a chunk of the request body. An empty ByteString returned when finished.

getRequestTrailers :: Request -> IO (Maybe HeaderTable)

Reading request trailers. This function must be called after getRequestBodyChunk returns an empty.

Aux

data Aux

Additional information.

auxTimeHandle :: Aux -> Handle

Time handle for the worker processing this request and response.

Response

data Response

HTTP response.

Creating response

responseNoBody :: Status -> ResponseHeaders -> Response

Creating response without body.

responseFile :: Status -> ResponseHeaders -> FileSpec -> Response

Creating response with file.

responseStreaming :: Status -> ResponseHeaders -> ((Builder -> IO ()) -> IO () -> IO ()) -> Response

Creating response with streaming.

responseBuilder :: Status -> ResponseHeaders -> Builder -> Response

Creating response with builder.

Accessing response

responseStatus :: Response -> Status

Accessor for response status.

responseBodySize :: Response -> Maybe Int

Getter for response body size. This value is available for file body.

Trailers maker

type TrailersMaker = Maybe ByteString -> IO NextTrailersMaker

Trailers maker. A chunks of the response body is passed with Just. The maker should update internal state with the ByteString and return the next trailers maker. When response body reaches its end, Nothing is passed and the maker should generate trailers. An example:

{-# LANGUAGE BangPatterns #-}
import Data.ByteString (ByteString)
import qualified Data.ByteString.Char8 as C8
import Crypto.Hash (Context, SHA1) -- cryptonite
import qualified Crypto.Hash as CH

-- Strictness is important for Context.
trailersMaker :: Context SHA1 -> Maybe ByteString -> IO NextTrailersMaker
trailersMaker ctx Nothing = return $ Trailers [("X-SHA1", sha1)]
  where
    !sha1 = C8.pack $ show $ CH.hashFinalize ctx
trailersMaker ctx (Just bs) = return $ NextTrailersMaker $ trailersMaker ctx'
  where
    !ctx' = CH.hashUpdate ctx bs

Usage example:

let h2rsp = responseFile ...
    maker = trailersMaker (CH.hashInit :: Context SHA1)
    h2rsp' = setResponseTrailersMaker h2rsp maker

data NextTrailersMaker

Either the next trailers maker or final trailers.

Constructors

NextTrailersMaker !TrailersMaker

Trailers ResponseHeaders

defaultTrailersMaker :: TrailersMaker

TrailersMake to create no trailers.

setResponseTrailersMaker :: Response -> TrailersMaker -> Response

Setting TrailersMaker to Response.

Push promise

data PushPromise

HTTP/2 push promise or sever push. Pseudo REQUEST headers in push promise is automatically generated. Then, a server push is sent according to promiseResponse.

pushPromise :: ByteString -> Response -> Weight -> PushPromise

Creating push promise.

promiseRequestPath :: PushPromise -> ByteString

Accessor for a URL path in a push promise (a virtual request from a server). E.g. "/style/default.css".

promiseResponse :: PushPromise -> Response

Accessor for response actually pushed from a server.

promiseWeight :: PushPromise -> Weight

Accessor for response weight.

Types

data FileSpec

File specification.

Constructors

FileSpec FilePath FileOffset ByteCount

Instances

Eq FileSpec

Defined in Network.HTTP2.Server.API

Methods

(==) :: FileSpec -> FileSpec -> Bool

(/=) :: FileSpec -> FileSpec -> Bool

Show FileSpec

Defined in Network.HTTP2.Server.API

Methods

showsPrec :: Int -> FileSpec -> ShowS

show :: FileSpec -> String

showList :: [FileSpec] -> ShowS

type FileOffset = Int64

Offset for file.

type ByteCount = Int64

How many bytes to read

RecvN

defaultReadN :: Socket -> IORef (Maybe ByteString) -> Int -> IO ByteString

Naive implementation for readN.

Position read for files

type PositionReadMaker = FilePath -> IO (PositionRead, Sentinel)

Making a position read and its closer.

type PositionRead = FileOffset -> ByteCount -> Buffer -> IO ByteCount

Position read for files.

data Sentinel

Manipulating a file resource.

Constructors

Closer (IO ())

Closing a file resource. Its refresher is automatiaclly generated by the internal timer.

Refresher (IO ())

Refreshing a file resource while reading. Closing the file must be done by its own timer or something.

defaultPositionReadMaker :: PositionReadMaker

Position read based on Handle.