{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE QuasiQuotes       #-}
{-# LANGUAGE TemplateHaskell   #-}

module Logging.TH
  ( logv
  , debug
  , info
  , warn
  , error
  , fatal
  ) where

import           Control.Monad.IO.Class (MonadIO)
import           Language.Haskell.TH

import           Logging.Internal
import           Logging.Types

import           Prelude                hiding (error, log)

-- | Log "message" with the severity "level".
--
-- The missing type signature: 'MonadIO' m => 'Logger' -> 'Level' -> 'String' -> m ()
logv :: ExpQ
logv = do
  loc <- location
  let filename = loc_filename loc
      packagename = loc_package loc
      modulename = loc_module loc
      lineno = fst $ loc_start loc
      location = (filename, packagename, modulename, lineno)
  [| \logger level msg -> log logger level msg location |]

-- | Log "message" with a specific severity.
--
-- The missing type signature: 'MonadIO' m => 'Logger' -> 'String' -> m ()
debug, info, warn, error, fatal :: ExpQ
debug = [| \logger -> $(logv) logger $ read "DEBUG" |]
info = [| \logger -> $(logv) logger $ read "INFO" |]
warn = [| \logger -> $(logv) logger $ read "WARN" |]
error = [| \logger -> $(logv) logger $ read "ERROR" |]
fatal = [| \logger -> $(logv) logger $ read "FATAL" |]