| Copyright | (c) Michael Weber <michael.weber@post.rwth-aachen.de> 2001 (c) Jeff Newbern 2003-2006 (c) Andriy Palamarchuk 2006 |
|---|---|
| License | BSD-style (see the file LICENSE) |
| Maintainer | ross@soi.city.ac.uk |
| Stability | experimental |
| Portability | non-portable (type families) |
| Safe Haskell | Safe-Inferred |
| Language | GHC2021 |
Control.Monad.Except
Description
- Computation type:
- Computations which may fail or throw exceptions.
- Binding strategy:
- Failure records information about the cause/location of the failure. Failure values bypass the bound function, other values are used as inputs to the bound function.
- Useful for:
- Building computations from sequences of functions that may fail or using exception handling to structure error handling.
- Zero and plus:
- Zero is represented by an empty error and the plus operation executes its second argument if the first fails.
- Example type:
EitherString a
The Error monad (also called the Exception monad).
Synopsis
- class Monad m => MonadError m where
- type ErrorType m
- throwError :: ErrorType m -> m a
- catchError :: m a -> (ErrorType m -> m a) -> m a
- tryError :: MonadError m => m a -> m (Either (ErrorType m) a)
- withError :: MonadError m => (ErrorType m -> ErrorType m) -> m a -> m a
- newtype ExceptT e (m :: Type -> Type) a = ExceptT (m (Either e a))
- runExceptT :: ExceptT e m a -> m (Either e a)
- mapExceptT :: (m (Either e a) -> n (Either e' b)) -> ExceptT e m a -> ExceptT e' n b
- withExceptT :: forall (m :: Type -> Type) e e' a. Functor m => (e -> e') -> ExceptT e m a -> ExceptT e' m a
- module Control.Monad
- module Control.Monad.Fix
- module Control.Monad.Trans
Monads with error handling
class Monad m => MonadError m where Source #
The strategy of combining computations that can throw exceptions by bypassing bound functions from the point an exception is thrown to the point that it is handled.
Is parameterized over the type of error information and
the monad type constructor.
It is common to use Either StringMonadError class.
You can also define your own a monad type constructor
other than Either eMonadError class.
Methods
throwError :: ErrorType m -> m a Source #
Is used within a monadic computation to begin exception processing.
catchError :: m a -> (ErrorType m -> m a) -> m a Source #
A handler function to handle previous errors and return to normal execution. A common idiom is:
do { action1; action2; action3 } `catchError` handlerwhere the action functions can call throwError.
Note that handler and the do-block must have the same return type.
Instances
| MonadError IO Source # | |
| MonadError (Either e) Source # | |
| MonadError m => MonadError (MaybeT m) Source # | |
| Monad m => MonadError (ExceptT e m) Source # | |
| MonadError m => MonadError (IdentityT m) Source # | |
| MonadError m => MonadError (ReaderT r m) Source # | |
| MonadError m => MonadError (StateT s m) Source # | |
| MonadError m => MonadError (StateT s m) Source # | |
| (Monoid w, MonadError m) => MonadError (WriterT w m) Source # | |
| (Monoid w, MonadError m) => MonadError (WriterT w m) Source # | |
| (Monoid w, MonadError m) => MonadError (RWST r w s m) Source # | |
| (Monoid w, MonadError m) => MonadError (RWST r w s m) Source # | |
tryError :: MonadError m => m a -> m (Either (ErrorType m) a) Source #
MonadError analogue to the try function.
withError :: MonadError m => (ErrorType m -> ErrorType m) -> m a -> m a Source #
MonadError analogue to the withExceptT function.
Modify the value (but not the type) of an error.
The type is fixed because of the ErrorType type family.
The ExceptT monad transformer
newtype ExceptT e (m :: Type -> Type) a #
A monad transformer that adds exceptions to other monads.
ExceptT constructs a monad parameterized over two things:
- e - The exception type.
- m - The inner monad.
The return function yields a computation that produces the given
value, while >>= sequences two subcomputations, exiting on the
first exception.
Instances
runExceptT :: ExceptT e m a -> m (Either e a) #
The inverse of ExceptT.
mapExceptT :: (m (Either e a) -> n (Either e' b)) -> ExceptT e m a -> ExceptT e' n b #
Map the unwrapped computation using the given function.
runExceptT(mapExceptTf m) = f (runExceptTm)
withExceptT :: forall (m :: Type -> Type) e e' a. Functor m => (e -> e') -> ExceptT e m a -> ExceptT e' m a #
Transform any exceptions thrown by the computation using the given function.
module Control.Monad
module Control.Monad.Fix
module Control.Monad.Trans
Example 1: Custom Error Data Type
Here is an example that demonstrates the use of a custom Error data type with
the throwError and catchError exception mechanism from MonadError.
The example throws an exception if the user enters an empty string
or a string longer than 5 characters. Otherwise it prints length of the string.
import Control.Monad.Except
-- This is the type to represent length calculation error.
data LengthError = EmptyString -- Entered string was empty.
| StringTooLong Int -- A string is longer than 5 characters.
-- Records a length of the string.
| OtherError String -- Other error, stores the problem description.
-- Converts LengthError to a readable message.
instance Show LengthError where
show EmptyString = "The string was empty!"
show (StringTooLong len) =
"The length of the string (" ++ (show len) ++ ") is bigger than 5!"
show (OtherError msg) = msg
-- For our monad type constructor, we use Either LengthError
-- which represents failure using Left LengthError
-- or a successful result of type a using Right a.
type LengthMonad = Either LengthError
main = do
putStrLn "Please enter a string:"
s <- getLine
reportResult (calculateLengthOrFail s)
-- Attempts to calculate length and throws an error if the provided string is
-- empty or longer than 5 characters.
-- The processing is done in Either monad.
calculateLengthOrFail :: String -> LengthMonad Int
calculateLengthOrFail [] = throwError EmptyString
calculateLengthOrFail s | len > 5 = throwError (StringTooLong len)
| otherwise = return len
where len = length s
-- Prints result of the string length calculation.
reportResult :: LengthMonad Int -> IO ()
reportResult (Right len) = putStrLn ("The length of the string is " ++ (show len))
reportResult (Left e) = putStrLn ("Length calculation failed with error: " ++ (show e))Example 2: Using ExceptT Monad Transformer
ErrorTIO monad:
import Control.Monad.Except
-- An IO monad which can return String failure.
-- It is convenient to define the monad type of the combined monad,
-- especially if we combine more monad transformers.
type LengthMonad = ExceptT String IO
main = do
-- runExceptT removes the ExceptT wrapper
r <- runExceptT calculateLength
reportResult r
-- Asks user for a non-empty string and returns its length.
-- Throws an error if user enters an empty string.
calculateLength :: LengthMonad Int
calculateLength = do
-- all the IO operations have to be lifted to the IO monad in the monad stack
liftIO $ putStrLn "Please enter a non-empty string: "
s <- liftIO getLine
if null s
then throwError "The string was empty!"
else return $ length s
-- Prints result of the string length calculation.
reportResult :: Either String Int -> IO ()
reportResult (Right len) = putStrLn ("The length of the string is " ++ (show len))
reportResult (Left e) = putStrLn ("Length calculation failed with error: " ++ (show e))