Algebra.Graph

Alga is a library for algebraic construction and manipulation of graphs in Haskell. See this paper for the motivation behind the library, the underlying theory, and implementation details.

This module defines the core data type Graph and associated algorithms. For graphs that are known to be non-empty at compile time, see Algebra.Graph.NonEmpty. Graph is an instance of type classes defined in modules Algebra.Graph.Class and Algebra.Graph.HigherKinded.Class, which can be used for polymorphic graph construction and manipulation.

Algebraic data type for graphs

data Graph a

The Graph data type is a deep embedding of the core graph construction primitives empty, vertex, overlay and connect. We define a Num instance as a convenient notation for working with graphs:

0           == Vertex 0
1 + 2       == Overlay (Vertex 1) (Vertex 2)
1 * 2       == Connect (Vertex 1) (Vertex 2)
1 + 2 * 3   == Overlay (Vertex 1) (Connect (Vertex 2) (Vertex 3))
1 * (2 + 3) == Connect (Vertex 1) (Overlay (Vertex 2) (Vertex 3))

The Eq instance is currently implemented using the AdjacencyMap as the canonical graph representation and satisfies all axioms of algebraic graphs:

• overlay is commutative and associative:

        x + y == y + x
  x + (y + z) == (x + y) + z

• connect is associative and has empty as the identity:

    x * empty == x
    empty * x == x
  x * (y * z) == (x * y) * z

• connect distributes over overlay:

  x * (y + z) == x * y + x * z
  (x + y) * z == x * z + y * z

• connect can be decomposed:

  x * y * z == x * y + x * z + y * z

The following useful theorems can be proved from the above set of axioms.

• overlay has empty as the identity and is idempotent:

    x + empty == x
    empty + x == x
        x + x == x

• Absorption and saturation of connect:

  x * y + x + y == x * y
      x * x * x == x * x

When specifying the time and memory complexity of graph algorithms, n will denote the number of vertices in the graph, m will denote the number of edges in the graph, and s will denote the size of the corresponding Graph expression. For example, if g is a Graph then n, m and s can be computed as follows:

n == vertexCount g
m == edgeCount g
s == size g

Note that size is slightly different from the length method of the Foldable type class, as the latter does not count empty leaves of the expression:

length empty           == 0
size   empty           == 1
length (vertex x)      == 1
size   (vertex x)      == 1
length (empty + empty) == 0
size   (empty + empty) == 2

The size of any graph is positive, and the difference (size g - length g) corresponds to the number of occurrences of empty in an expression g.

Converting a Graph to the corresponding AdjacencyMap takes O(s + m * log(m)) time and O(s + m) memory. This is also the complexity of the graph equality test, because it is currently implemented by converting graph expressions to canonical representations based on adjacency maps.

Constructors

Empty

Vertex a

Overlay (Graph a) (Graph a)

Connect (Graph a) (Graph a)

Instances

Monad Graph

Defined in Algebra.Graph

Methods

(>>=) :: Graph a -> (a -> Graph b) -> Graph b

(>>) :: Graph a -> Graph b -> Graph b

return :: a -> Graph a

fail :: String -> Graph a

Functor Graph

Defined in Algebra.Graph

Methods

fmap :: (a -> b) -> Graph a -> Graph b

(<$) :: a -> Graph b -> Graph a

Applicative Graph

Defined in Algebra.Graph

Methods

pure :: a -> Graph a

(<*>) :: Graph (a -> b) -> Graph a -> Graph b

liftA2 :: (a -> b -> c) -> Graph a -> Graph b -> Graph c

(*>) :: Graph a -> Graph b -> Graph b

(<*) :: Graph a -> Graph b -> Graph a

Foldable Graph

Defined in Algebra.Graph

Methods

fold :: Monoid m => Graph m -> m

foldMap :: Monoid m => (a -> m) -> Graph a -> m

foldr :: (a -> b -> b) -> b -> Graph a -> b

foldr' :: (a -> b -> b) -> b -> Graph a -> b

foldl :: (b -> a -> b) -> b -> Graph a -> b

foldl' :: (b -> a -> b) -> b -> Graph a -> b

foldr1 :: (a -> a -> a) -> Graph a -> a

foldl1 :: (a -> a -> a) -> Graph a -> a

toList :: Graph a -> [a]

null :: Graph a -> Bool

length :: Graph a -> Int

elem :: Eq a => a -> Graph a -> Bool

maximum :: Ord a => Graph a -> a

minimum :: Ord a => Graph a -> a

sum :: Num a => Graph a -> a

product :: Num a => Graph a -> a

Traversable Graph

Defined in Algebra.Graph

Methods

traverse :: Applicative f => (a -> f b) -> Graph a -> f (Graph b)

sequenceA :: Applicative f => Graph (f a) -> f (Graph a)

mapM :: Monad m => (a -> m b) -> Graph a -> m (Graph b)

sequence :: Monad m => Graph (m a) -> m (Graph a)

Alternative Graph

Defined in Algebra.Graph

Methods

empty :: Graph a

(<|>) :: Graph a -> Graph a -> Graph a

some :: Graph a -> Graph [a]

many :: Graph a -> Graph [a]

MonadPlus Graph

Defined in Algebra.Graph

Methods

mzero :: Graph a

mplus :: Graph a -> Graph a -> Graph a

Graph Graph

Defined in Algebra.Graph.HigherKinded.Class

Methods

connect :: Graph a -> Graph a -> Graph a

Ord a => Eq (Graph a)

Defined in Algebra.Graph

Methods

(==) :: Graph a -> Graph a -> Bool

(/=) :: Graph a -> Graph a -> Bool

Num a => Num (Graph a)

Defined in Algebra.Graph

Methods

(+) :: Graph a -> Graph a -> Graph a

(-) :: Graph a -> Graph a -> Graph a

(*) :: Graph a -> Graph a -> Graph a

negate :: Graph a -> Graph a

abs :: Graph a -> Graph a

signum :: Graph a -> Graph a

fromInteger :: Integer -> Graph a

Show a => Show (Graph a)

Defined in Algebra.Graph

Methods

showsPrec :: Int -> Graph a -> ShowS

show :: Graph a -> String

showList :: [Graph a] -> ShowS

NFData a => NFData (Graph a)

Defined in Algebra.Graph

Methods

rnf :: Graph a -> ()

Ord a => ToGraph (Graph a)

Defined in Algebra.Graph.ToGraph

Associated Types

type ToVertex (Graph a) :: *

Methods

toGraph :: Graph a -> Graph (ToVertex (Graph a))

foldg :: r -> (ToVertex (Graph a) -> r) -> (r -> r -> r) -> (r -> r -> r) -> Graph a -> r

isEmpty :: Graph a -> Bool

size :: Graph a -> Int

hasVertex :: ToVertex (Graph a) -> Graph a -> Bool

hasEdge :: ToVertex (Graph a) -> ToVertex (Graph a) -> Graph a -> Bool

vertexCount :: Graph a -> Int

edgeCount :: Graph a -> Int

vertexList :: Graph a -> [ToVertex (Graph a)]

edgeList :: Graph a -> [(ToVertex (Graph a), ToVertex (Graph a))]

vertexSet :: Graph a -> Set (ToVertex (Graph a))

vertexIntSet :: Graph a -> IntSet

edgeSet :: Graph a -> Set (ToVertex (Graph a), ToVertex (Graph a))

preSet :: ToVertex (Graph a) -> Graph a -> Set (ToVertex (Graph a))

preIntSet :: Int -> Graph a -> IntSet

postSet :: ToVertex (Graph a) -> Graph a -> Set (ToVertex (Graph a))

postIntSet :: Int -> Graph a -> IntSet

adjacencyList :: Graph a -> [(ToVertex (Graph a), [ToVertex (Graph a)])]

adjacencyMap :: Graph a -> Map (ToVertex (Graph a)) (Set (ToVertex (Graph a)))

adjacencyIntMap :: Graph a -> IntMap IntSet

adjacencyMapTranspose :: Graph a -> Map (ToVertex (Graph a)) (Set (ToVertex (Graph a)))

adjacencyIntMapTranspose :: Graph a -> IntMap IntSet

dfsForest :: Graph a -> Forest (ToVertex (Graph a))

dfsForestFrom :: [ToVertex (Graph a)] -> Graph a -> Forest (ToVertex (Graph a))

dfs :: [ToVertex (Graph a)] -> Graph a -> [ToVertex (Graph a)]

reachable :: ToVertex (Graph a) -> Graph a -> [ToVertex (Graph a)]

topSort :: Graph a -> Maybe [ToVertex (Graph a)]

isAcyclic :: Graph a -> Bool

toAdjacencyMap :: Graph a -> AdjacencyMap (ToVertex (Graph a))

toAdjacencyMapTranspose :: Graph a -> AdjacencyMap (ToVertex (Graph a))

toAdjacencyIntMap :: Graph a -> AdjacencyIntMap

toAdjacencyIntMapTranspose :: Graph a -> AdjacencyIntMap

isDfsForestOf :: Forest (ToVertex (Graph a)) -> Graph a -> Bool

isTopSortOf :: [ToVertex (Graph a)] -> Graph a -> Bool

Graph (Graph a)

Defined in Algebra.Graph.Class

Associated Types

type Vertex (Graph a) :: *

Methods

empty :: Graph a

vertex :: Vertex (Graph a) -> Graph a

overlay :: Graph a -> Graph a -> Graph a

connect :: Graph a -> Graph a -> Graph a

type ToVertex (Graph a)

Defined in Algebra.Graph.ToGraph

type ToVertex (Graph a) = a

type Vertex (Graph a)

Defined in Algebra.Graph.Class

type Vertex (Graph a) = a

Basic graph construction primitives

empty :: Graph a

Construct the empty graph. An alias for the constructor Empty. Complexity: O(1) time, memory and size.

isEmpty     empty == True
hasVertex x empty == False
vertexCount empty == 0
edgeCount   empty == 0
size        empty == 1

vertex :: a -> Graph a

Construct the graph comprising a single isolated vertex. An alias for the constructor Vertex. Complexity: O(1) time, memory and size.

isEmpty     (vertex x) == False
hasVertex x (vertex x) == True
vertexCount (vertex x) == 1
edgeCount   (vertex x) == 0
size        (vertex x) == 1

edge :: a -> a -> Graph a

Construct the graph comprising a single edge. Complexity: O(1) time, memory and size.

edge x y               == connect (vertex x) (vertex y)
hasEdge x y (edge x y) == True
edgeCount   (edge x y) == 1
vertexCount (edge 1 1) == 1
vertexCount (edge 1 2) == 2

overlay :: Graph a -> Graph a -> Graph a

Overlay two graphs. An alias for the constructor Overlay. This is a commutative, associative and idempotent operation with the identity empty. Complexity: O(1) time and memory, O(s1 + s2) size.

isEmpty     (overlay x y) == isEmpty   x   && isEmpty   y
hasVertex z (overlay x y) == hasVertex z x || hasVertex z y
vertexCount (overlay x y) >= vertexCount x
vertexCount (overlay x y) <= vertexCount x + vertexCount y
edgeCount   (overlay x y) >= edgeCount x
edgeCount   (overlay x y) <= edgeCount x   + edgeCount y
size        (overlay x y) == size x        + size y
vertexCount (overlay 1 2) == 2
edgeCount   (overlay 1 2) == 0

connect :: Graph a -> Graph a -> Graph a

Connect two graphs. An alias for the constructor Connect. This is an associative operation with the identity empty, which distributes over overlay and obeys the decomposition axiom. Complexity: O(1) time and memory, O(s1 + s2) size. Note that the number of edges in the resulting graph is quadratic with respect to the number of vertices of the arguments: m = O(m1 + m2 + n1 * n2).

isEmpty     (connect x y) == isEmpty   x   && isEmpty   y
hasVertex z (connect x y) == hasVertex z x || hasVertex z y
vertexCount (connect x y) >= vertexCount x
vertexCount (connect x y) <= vertexCount x + vertexCount y
edgeCount   (connect x y) >= edgeCount x
edgeCount   (connect x y) >= edgeCount y
edgeCount   (connect x y) >= vertexCount x * vertexCount y
edgeCount   (connect x y) <= vertexCount x * vertexCount y + edgeCount x + edgeCount y
size        (connect x y) == size x        + size y
vertexCount (connect 1 2) == 2
edgeCount   (connect 1 2) == 1

vertices :: [a] -> Graph a

Construct the graph comprising a given list of isolated vertices. Complexity: O(L) time, memory and size, where L is the length of the given list.

vertices []            == empty
vertices [x]           == vertex x
hasVertex x . vertices == elem x
vertexCount . vertices == length . nub
vertexSet   . vertices == Set.fromList

edges :: [(a, a)] -> Graph a

Construct the graph from a list of edges. Complexity: O(L) time, memory and size, where L is the length of the given list.

edges []          == empty
edges [(x,y)]     == edge x y
edgeCount . edges == length . nub

overlays :: [Graph a] -> Graph a

Overlay a given list of graphs. Complexity: O(L) time and memory, and O(S) size, where L is the length of the given list, and S is the sum of sizes of the graphs in the list.

overlays []        == empty
overlays [x]       == x
overlays [x,y]     == overlay x y
overlays           == foldr overlay empty
isEmpty . overlays == all isEmpty

connects :: [Graph a] -> Graph a

Connect a given list of graphs. Complexity: O(L) time and memory, and O(S) size, where L is the length of the given list, and S is the sum of sizes of the graphs in the list.

connects []        == empty
connects [x]       == x
connects [x,y]     == connect x y
connects           == foldr connect empty
isEmpty . connects == all isEmpty

Graph folding

foldg :: b -> (a -> b) -> (b -> b -> b) -> (b -> b -> b) -> Graph a -> b

Generalised Graph folding: recursively collapse a Graph by applying the provided functions to the leaves and internal nodes of the expression. The order of arguments is: empty, vertex, overlay and connect. Complexity: O(s) applications of given functions. As an example, the complexity of size is O(s), since all functions have cost O(1).

foldg empty vertex        overlay connect        == id
foldg empty vertex        overlay (flip connect) == transpose
foldg []    return        (++)    (++)           == toList
foldg 0     (const 1)     (+)     (+)            == length
foldg 1     (const 1)     (+)     (+)            == size
foldg True  (const False) (&&)    (&&)           == isEmpty

Relations on graphs

isSubgraphOf :: Ord a => Graph a -> Graph a -> Bool

The isSubgraphOf function takes two graphs and returns True if the first graph is a subgraph of the second. Complexity: O(s + m * log(m)) time. Note that the number of edges m of a graph can be quadratic with respect to the expression size s.

isSubgraphOf empty         x             == True
isSubgraphOf (vertex x)    empty         == False
isSubgraphOf x             (overlay x y) == True
isSubgraphOf (overlay x y) (connect x y) == True
isSubgraphOf (path xs)     (circuit xs)  == True

(===) :: Eq a => Graph a -> Graph a -> Bool infix 4

Structural equality on graph expressions. Complexity: O(s) time.

    x === x         == True
    x === x + empty == False
x + y === x + y     == True
1 + 2 === 2 + 1     == False
x + y === x * y     == False

Graph properties

isEmpty :: Graph a -> Bool

Check if a graph is empty. A convenient alias for null. Complexity: O(s) time.

isEmpty empty                       == True
isEmpty (overlay empty empty)       == True
isEmpty (vertex x)                  == False
isEmpty (removeVertex x $ vertex x) == True
isEmpty (removeEdge x y $ edge x y) == False

size :: Graph a -> Int

The size of a graph, i.e. the number of leaves of the expression including empty leaves. Complexity: O(s) time.

size empty         == 1
size (vertex x)    == 1
size (overlay x y) == size x + size y
size (connect x y) == size x + size y
size x             >= 1
size x             >= vertexCount x

hasVertex :: Eq a => a -> Graph a -> Bool

Check if a graph contains a given vertex. A convenient alias for elem. Complexity: O(s) time.

hasVertex x empty            == False
hasVertex x (vertex x)       == True
hasVertex 1 (vertex 2)       == False
hasVertex x . removeVertex x == const False

hasEdge :: Eq a => a -> a -> Graph a -> Bool

Check if a graph contains a given edge. Complexity: O(s) time.

hasEdge x y empty            == False
hasEdge x y (vertex z)       == False
hasEdge x y (edge x y)       == True
hasEdge x y . removeEdge x y == const False
hasEdge x y                  == elem (x,y) . edgeList

vertexCount :: Ord a => Graph a -> Int

The number of vertices in a graph. Complexity: O(s * log(n)) time.

vertexCount empty      == 0
vertexCount (vertex x) == 1
vertexCount            == length . vertexList

edgeCount :: Ord a => Graph a -> Int

The number of edges in a graph. Complexity: O(s + m * log(m)) time. Note that the number of edges m of a graph can be quadratic with respect to the expression size s.

edgeCount empty      == 0
edgeCount (vertex x) == 0
edgeCount (edge x y) == 1
edgeCount            == length . edgeList

vertexList :: Ord a => Graph a -> [a]

The sorted list of vertices of a given graph. Complexity: O(s * log(n)) time and O(n) memory.

vertexList empty      == []
vertexList (vertex x) == [x]
vertexList . vertices == nub . sort

edgeList :: Ord a => Graph a -> [(a, a)]

The sorted list of edges of a graph. Complexity: O(s + m * log(m)) time and O(m) memory. Note that the number of edges m of a graph can be quadratic with respect to the expression size s.

edgeList empty          == []
edgeList (vertex x)     == []
edgeList (edge x y)     == [(x,y)]
edgeList (star 2 [3,1]) == [(2,1), (2,3)]
edgeList . edges        == nub . sort
edgeList . transpose    == sort . map swap . edgeList

vertexSet :: Ord a => Graph a -> Set a

The set of vertices of a given graph. Complexity: O(s * log(n)) time and O(n) memory.

vertexSet empty      == Set.empty
vertexSet . vertex   == Set.singleton
vertexSet . vertices == Set.fromList
vertexSet . clique   == Set.fromList

vertexIntSet :: Graph Int -> IntSet

The set of vertices of a given graph. Like vertexSet but specialised for graphs with vertices of type Int. Complexity: O(s * log(n)) time and O(n) memory.

vertexIntSet empty      == IntSet.empty
vertexIntSet . vertex   == IntSet.singleton
vertexIntSet . vertices == IntSet.fromList
vertexIntSet . clique   == IntSet.fromList

edgeSet :: Ord a => Graph a -> Set (a, a)

The set of edges of a given graph. Complexity: O(s * log(m)) time and O(m) memory.

edgeSet empty      == Set.empty
edgeSet (vertex x) == Set.empty
edgeSet (edge x y) == Set.singleton (x,y)
edgeSet . edges    == Set.fromList

adjacencyList :: Ord a => Graph a -> [(a, [a])]

The sorted adjacency list of a graph. Complexity: O(n + m) time and O(m) memory.

adjacencyList empty          == []
adjacencyList (vertex x)     == [(x, [])]
adjacencyList (edge 1 2)     == [(1, [2]), (2, [])]
adjacencyList (star 2 [3,1]) == [(1, []), (2, [1,3]), (3, [])]
stars . adjacencyList        == id

adjacencyMap :: Ord a => Graph a -> Map a (Set a)

The adjacency map of a graph: each vertex is associated with a set of its direct successors. Complexity: O(s + m * log(m)) time. Note that the number of edges m of a graph can be quadratic with respect to the expression size s.

adjacencyIntMap :: Graph Int -> IntMap IntSet

Like adjacencyMap but specialised for graphs with vertices of type Int.

Standard families of graphs

path :: [a] -> Graph a

The path on a list of vertices. Complexity: O(L) time, memory and size, where L is the length of the given list.

path []        == empty
path [x]       == vertex x
path [x,y]     == edge x y
path . reverse == transpose . path

circuit :: [a] -> Graph a

The circuit on a list of vertices. Complexity: O(L) time, memory and size, where L is the length of the given list.

circuit []        == empty
circuit [x]       == edge x x
circuit [x,y]     == edges [(x,y), (y,x)]
circuit . reverse == transpose . circuit

clique :: [a] -> Graph a

The clique on a list of vertices. Complexity: O(L) time, memory and size, where L is the length of the given list.

clique []         == empty
clique [x]        == vertex x
clique [x,y]      == edge x y
clique [x,y,z]    == edges [(x,y), (x,z), (y,z)]
clique (xs ++ ys) == connect (clique xs) (clique ys)
clique . reverse  == transpose . clique

biclique :: [a] -> [a] -> Graph a

The biclique on two lists of vertices. Complexity: O(L1 + L2) time, memory and size, where L1 and L2 are the lengths of the given lists.

biclique []      []      == empty
biclique [x]     []      == vertex x
biclique []      [y]     == vertex y
biclique [x1,x2] [y1,y2] == edges [(x1,y1), (x1,y2), (x2,y1), (x2,y2)]
biclique xs      ys      == connect (vertices xs) (vertices ys)

star :: a -> [a] -> Graph a

The star formed by a centre vertex connected to a list of leaves. Complexity: O(L) time, memory and size, where L is the length of the given list.

star x []    == vertex x
star x [y]   == edge x y
star x [y,z] == edges [(x,y), (x,z)]
star x ys    == connect (vertex x) (vertices ys)

stars :: [(a, [a])] -> Graph a

The stars formed by overlaying a list of stars. An inverse of adjacencyList. Complexity: O(L) time, memory and size, where L is the total size of the input.

stars []                      == empty
stars [(x, [])]               == vertex x
stars [(x, [y])]              == edge x y
stars [(x, ys)]               == star x ys
stars                         == overlays . map (uncurry star)
stars . adjacencyList         == id
overlay (stars xs) (stars ys) == stars (xs ++ ys)

tree :: Tree a -> Graph a

The tree graph constructed from a given Tree data structure. Complexity: O(T) time, memory and size, where T is the size of the given tree (i.e. the number of vertices in the tree).

tree (Node x [])                                         == vertex x
tree (Node x [Node y [Node z []]])                       == path [x,y,z]
tree (Node x [Node y [], Node z []])                     == star x [y,z]
tree (Node 1 [Node 2 [], Node 3 [Node 4 [], Node 5 []]]) == edges [(1,2), (1,3), (3,4), (3,5)]

forest :: Forest a -> Graph a

The forest graph constructed from a given Forest data structure. Complexity: O(F) time, memory and size, where F is the size of the given forest (i.e. the number of vertices in the forest).

forest []                                                  == empty
forest [x]                                                 == tree x
forest [Node 1 [Node 2 [], Node 3 []], Node 4 [Node 5 []]] == edges [(1,2), (1,3), (4,5)]
forest                                                     == overlays . map tree

mesh :: [a] -> [b] -> Graph (a, b)

Construct a mesh graph from two lists of vertices. Complexity: O(L1 * L2) time, memory and size, where L1 and L2 are the lengths of the given lists.

mesh xs     []   == empty
mesh []     ys   == empty
mesh [x]    [y]  == vertex (x, y)
mesh xs     ys   == box (path xs) (path ys)
mesh [1..3] "ab" == edges [ ((1,'a'),(1,'b')), ((1,'a'),(2,'a')), ((1,'b'),(2,'b')), ((2,'a'),(2,'b'))
                          , ((2,'a'),(3,'a')), ((2,'b'),(3,'b')), ((3,'a'),(3,'b')) ]

torus :: [a] -> [b] -> Graph (a, b)

Construct a torus graph from two lists of vertices. Complexity: O(L1 * L2) time, memory and size, where L1 and L2 are the lengths of the given lists.

torus xs    []   == empty
torus []    ys   == empty
torus [x]   [y]  == edge (x,y) (x,y)
torus xs    ys   == box (circuit xs) (circuit ys)
torus [1,2] "ab" == edges [ ((1,'a'),(1,'b')), ((1,'a'),(2,'a')), ((1,'b'),(1,'a')), ((1,'b'),(2,'b'))
                          , ((2,'a'),(1,'a')), ((2,'a'),(2,'b')), ((2,'b'),(1,'b')), ((2,'b'),(2,'a')) ]

deBruijn :: Int -> [a] -> Graph [a]

Construct a De Bruijn graph of a given non-negative dimension using symbols from a given alphabet. Complexity: O(A^(D + 1)) time, memory and size, where A is the size of the alphabet and D is the dimension of the graph.

          deBruijn 0 xs               == edge [] []
n > 0 ==> deBruijn n []               == empty
          deBruijn 1 [0,1]            == edges [ ([0],[0]), ([0],[1]), ([1],[0]), ([1],[1]) ]
          deBruijn 2 "0"              == edge "00" "00"
          deBruijn 2 "01"             == edges [ ("00","00"), ("00","01"), ("01","10"), ("01","11")
                                               , ("10","00"), ("10","01"), ("11","10"), ("11","11") ]
          transpose   (deBruijn n xs) == fmap reverse $ deBruijn n xs
          vertexCount (deBruijn n xs) == (length $ nub xs)^n
n > 0 ==> edgeCount   (deBruijn n xs) == (length $ nub xs)^(n + 1)

Graph transformation

removeVertex :: Eq a => a -> Graph a -> Graph a

Remove a vertex from a given graph. Complexity: O(s) time, memory and size.

removeVertex x (vertex x)       == empty
removeVertex 1 (vertex 2)       == vertex 2
removeVertex x (edge x x)       == empty
removeVertex 1 (edge 1 2)       == vertex 2
removeVertex x . removeVertex x == removeVertex x

removeEdge :: Eq a => a -> a -> Graph a -> Graph a

Remove an edge from a given graph. Complexity: O(s) time, memory and size.

removeEdge x y (edge x y)       == vertices [x,y]
removeEdge x y . removeEdge x y == removeEdge x y
removeEdge x y . removeVertex x == removeVertex x
removeEdge 1 1 (1 * 1 * 2 * 2)  == 1 * 2 * 2
removeEdge 1 2 (1 * 1 * 2 * 2)  == 1 * 1 + 2 * 2
size (removeEdge x y z)         <= 3 * size z

replaceVertex :: Eq a => a -> a -> Graph a -> Graph a

The function replaceVertex x y replaces vertex x with vertex y in a given Graph. If y already exists, x and y will be merged. Complexity: O(s) time, memory and size.

replaceVertex x x            == id
replaceVertex x y (vertex x) == vertex y
replaceVertex x y            == mergeVertices (== x) y

mergeVertices :: (a -> Bool) -> a -> Graph a -> Graph a

Merge vertices satisfying a given predicate into a given vertex. Complexity: O(s) time, memory and size, assuming that the predicate takes O(1) to be evaluated.

mergeVertices (const False) x    == id
mergeVertices (== x) y           == replaceVertex x y
mergeVertices even 1 (0 * 2)     == 1 * 1
mergeVertices odd  1 (3 + 4 * 5) == 4 * 1

splitVertex :: Eq a => a -> [a] -> Graph a -> Graph a

Split a vertex into a list of vertices with the same connectivity. Complexity: O(s + k * L) time, memory and size, where k is the number of occurrences of the vertex in the expression and L is the length of the given list.

splitVertex x []                  == removeVertex x
splitVertex x [x]                 == id
splitVertex x [y]                 == replaceVertex x y
splitVertex 1 [0,1] $ 1 * (2 + 3) == (0 + 1) * (2 + 3)

transpose :: Graph a -> Graph a

Transpose a given graph. Complexity: O(s) time, memory and size.

transpose empty       == empty
transpose (vertex x)  == vertex x
transpose (edge x y)  == edge y x
transpose . transpose == id
transpose (box x y)   == box (transpose x) (transpose y)
edgeList . transpose  == sort . map swap . edgeList

induce :: (a -> Bool) -> Graph a -> Graph a

Construct the induced subgraph of a given graph by removing the vertices that do not satisfy a given predicate. Complexity: O(s) time, memory and size, assuming that the predicate takes O(1) to be evaluated.

induce (const True ) x      == x
induce (const False) x      == empty
induce (/= x)               == removeVertex x
induce p . induce q         == induce (\x -> p x && q x)
isSubgraphOf (induce p x) x == True

simplify :: Ord a => Graph a -> Graph a

Simplify a graph expression. Semantically, this is the identity function, but it simplifies a given expression according to the laws of the algebra. The function does not compute the simplest possible expression, but uses heuristics to obtain useful simplifications in reasonable time. Complexity: the function performs O(s) graph comparisons. It is guaranteed that the size of the result does not exceed the size of the given expression.

simplify              == id
size (simplify x)     <= size x
simplify empty       === empty
simplify 1           === 1
simplify (1 + 1)     === 1
simplify (1 + 2 + 1) === 1 + 2
simplify (1 * 1 * 1) === 1 * 1

sparsify :: Graph a -> Graph (Either Int a)

Sparsify a graph by adding intermediate Left Int vertices between the original vertices (wrapping the latter in Right) such that the resulting graph is sparse, i.e. contains only O(s) edges, but preserves the reachability relation between the original vertices. Sparsification is useful when working with dense graphs, as it can reduce the number of edges from O(n^2) down to O(n) by replacing cliques, bicliques and similar densely connected structures by sparse subgraphs built out of intermediate vertices. Complexity: O(s) time, memory and size.

sort . reachable x       == sort . rights . reachable (Right x) . sparsify
vertexCount (sparsify x) <= vertexCount x + size x + 1
edgeCount   (sparsify x) <= 3 * size x
size        (sparsify x) <= 3 * size x

Graph composition

box :: Graph a -> Graph b -> Graph (a, b)

Compute the Cartesian product of graphs. Complexity: O(s1 * s2) time, memory and size, where s1 and s2 are the sizes of the given graphs.

box (path [0,1]) (path "ab") == edges [ ((0,'a'), (0,'b'))
                                      , ((0,'a'), (1,'a'))
                                      , ((0,'b'), (1,'b'))
                                      , ((1,'a'), (1,'b')) ]

Up to an isomorphism between the resulting vertex types, this operation is commutative, associative, distributes over overlay, has singleton graphs as identities and empty as the annihilating zero. Below ~~ stands for the equality up to an isomorphism, e.g. (x, ()) ~~ x.

box x y               ~~ box y x
box x (box y z)       ~~ box (box x y) z
box x (overlay y z)   == overlay (box x y) (box x z)
box x (vertex ())     ~~ x
box x empty           ~~ empty
transpose   (box x y) == box (transpose x) (transpose y)
vertexCount (box x y) == vertexCount x * vertexCount y
edgeCount   (box x y) <= vertexCount x * edgeCount y + edgeCount x * vertexCount y

Context

data Context a

The context of a subgraph comprises the input and output vertices outside the subgraph that are connected to the vertices inside the subgraph.

Constructors

Context

Fields

• inputs :: [a]
• outputs :: [a]

context :: (a -> Bool) -> Graph a -> Maybe (Context a)

Extract the context from a graph Focus. Returns Nothing if the focus could not be obtained.