Hasql.Encoders

A DSL for declaration of query parameter encoders.

Params

data Params a

Encoder of some representation of the parameters product.

Has instances of Contravariant, Divisible and Monoid, which you can use to compose multiple parameters together. E.g.,

someParamsEncoder :: Params (Int64, Maybe Text)
someParamsEncoder =
  contramap fst (value int8) <>
  contramap snd (nullableValue text)

As a general solution for tuples of any arity, instead of fst and snd, consider the functions of the contrazip family from the "contravariant-extras" package. E.g., here's how you can achieve the same as the above:

someParamsEncoder :: Params (Int64, Maybe Text)
someParamsEncoder =
  contrazip2 (value int8) (nullableValue text)

Here's how you can implement encoders for custom composite types:

data Person =
  Person { name :: Text, gender :: Gender, age :: Int }

data Gender =
  Male | Female

personParams :: Params Person
personParams =
  contramap name (value text) <>
  contramap gender (value genderValue) <>
  contramap (fromIntegral . age) (value int8)

genderValue :: Value Gender
genderValue =
  contramap genderText text
  where
    genderText gender =
      case gender of
        Male -> "male"
        Female -> "female"

Instances

Divisible Params

Contravariant Params

Monoid (Params a)

Default (Params ())

Maps to unit.

(Default (Value a1), Default (Value a2)) => Default (Params (a1, a2))

(Default (Value a1), Default (Value a2), Default (Value a3)) => Default (Params (a1, a2, a3))

(Default (Value a1), Default (Value a2), Default (Value a3), Default (Value a4)) => Default (Params (a1, a2, a3, a4))

(Default (Value a1), Default (Value a2), Default (Value a3), Default (Value a4), Default (Value a5)) => Default (Params (a1, a2, a3, a4, a5))

Default (Value a) => Default (Params (Identity a))

unit :: Params ()

Encode no parameters.

value :: Value a -> Params a

Lift an individual value encoder to a parameters encoder.

nullableValue :: Value a -> Params (Maybe a)

Lift an individual nullable value encoder to a parameters encoder.

Value

data Value a

An individual value encoder. Will be mapped to a single placeholder in the query.

Instances

Contravariant Value

Default (Value Bool)

Maps to bool.

Default (Value Char)

Maps to char.

Default (Value Double)

Maps to float8.

Default (Value Float)

Maps to float4.

Default (Value Int16)

Maps to int2.

Default (Value Int32)

Maps to int4.

Default (Value Int64)

Maps to int8.

Default (Value (TimeOfDay, TimeZone))

Maps to timetz.

Default (Value ByteString)

Maps to bytea.

Default (Value Scientific)

Maps to numeric.

Default (Value Text)

Maps to text.

Default (Value UTCTime)

Maps to timestamptz.

Default (Value Value)

Maps to json.

Default (Value UUID)

Maps to uuid.

Default (Value DiffTime)

Maps to interval.

Default (Value Day)

Maps to date.

Default (Value TimeOfDay)

Maps to time.

Default (Value LocalTime)

Maps to timestamp.

bool :: Value Bool

Encoder of BOOL values.

int2 :: Value Int16

Encoder of INT2 values.

int4 :: Value Int32

Encoder of INT4 values.

int8 :: Value Int64

Encoder of INT8 values.

float4 :: Value Float

Encoder of FLOAT4 values.

float8 :: Value Double

Encoder of FLOAT8 values.

numeric :: Value Scientific

Encoder of NUMERIC values.

char :: Value Char

Encoder of CHAR values. Note that it supports UTF-8 values and identifies itself under the TEXT OID because of that.

text :: Value Text

Encoder of TEXT values.

bytea :: Value ByteString

Encoder of BYTEA values.

date :: Value Day

Encoder of DATE values.

timestamp :: Value LocalTime

Encoder of TIMESTAMP values.

timestamptz :: Value UTCTime

Encoder of TIMESTAMPTZ values.

time :: Value TimeOfDay

Encoder of TIME values.

timetz :: Value (TimeOfDay, TimeZone)

Encoder of TIMETZ values.

interval :: Value DiffTime

Encoder of INTERVAL values.

uuid :: Value UUID

Encoder of UUID values.

json :: Value Value

Encoder of JSON values.

jsonb :: Value Value

Encoder of JSONB values.

array :: Array a -> Value a

Unlifts the Array encoder to the plain Value encoder.

enum :: (a -> Text) -> Value a

Given a function, which maps the value into the textual enum label from the DB side, produces a encoder of that value.

unknown :: Value ByteString

Identifies the value with the PostgreSQL's "unknown" type, thus leaving it up to Postgres to infer the actual type of the value.

The bytestring needs to be encoded according to the Postgres' binary format of the type it expects.

Essentially this is a low-level hook for encoding of values with custom codecs. The "postgresql-binary" library will provide you with the toolchain.

Array

data Array a

A generic array encoder.

Here's an example of its usage:

x :: Value [[Int64]]
x =
  array (arrayDimension foldl' (arrayDimension foldl' (arrayValue int8)))

arrayValue :: Value a -> Array a

Lifts the Value encoder into the Array encoder of a non-nullable value.

arrayNullableValue :: Value a -> Array (Maybe a)

Lifts the Value encoder into the Array encoder of a nullable value.

arrayDimension :: (forall a. (a -> b -> a) -> a -> c -> a) -> Array b -> Array c

An encoder of an array dimension, which thus provides support for multidimensional arrays.

Accepts:

• An implementation of the left-fold operation, such as Data.Foldable.foldl', which determines the input value.
• A component encoder, which can be either another arrayDimension, arrayValue or arrayNullableValue.