module Development.Shake.Plus.FileRules (
need
, want
, needP
, wantP
, needIn
, wantIn
, (%>)
, (|%>)
, (%^>)
, (|%^>)
, phony
) where
import Control.Comonad.Env as E
import Control.Exception.Extra
import qualified Development.Shake
import qualified Development.Shake.FilePath
import Development.Shake.Plus.Core
import Path
import RIO as R
import Within
need :: (Partial, MonadAction m) => [String] -> m ()
need = liftAction . Development.Shake.need
want :: (Partial, MonadRules m) => [String] -> m ()
want = liftRules . Development.Shake.want
needP :: (Partial, MonadAction m) => [Path Rel File] -> m ()
needP = need . map toFilePath
wantP :: (Partial, MonadRules m) => [Path Rel File] -> m ()
wantP = want . map toFilePath
needIn :: (Partial, MonadAction m) => Path Rel Dir -> [Path Rel File] -> m ()
needIn x = needP . fmap (x </>)
wantIn :: (Partial, MonadRules m) => Path Rel Dir -> [Path Rel File] -> m ()
wantIn x = wantP . fmap (x </>)
(%>) :: (Partial, MonadReader r m, MonadRules m) => FilePattern -> (Path Rel File -> RAction r ()) -> m ()
(%>) x ract = R.ask >>= \r -> liftRules $ x Development.Shake.%> (runRAction r . (ract <=< parseRelFile))
(|%>) :: (Partial, MonadReader r m, MonadRules m) => [FilePattern] -> (Path Rel File -> RAction r ()) -> m ()
(|%>) x ract = R.ask >>= \r -> liftRules $ x Development.Shake.|%> (runRAction r . (ract <=< parseRelFile))
(%^>) :: (Partial, MonadReader r m, MonadRules m) => Within Rel FilePattern -> (Within Rel (Path Rel File) -> RAction r ()) -> m ()
(%^>) xs ract = liftA2 (Development.Shake.FilePath.</>) (toFilePath . E.ask) extract xs %> (ract <=< (`asWithin` E.ask xs))
(|%^>) :: (Partial, MonadReader r m, MonadRules m) => Within Rel [FilePattern] -> (Within Rel (Path Rel File) -> RAction r ()) -> m ()
(|%^>) xs ract = ((Development.Shake.FilePath.</>) (toFilePath . E.ask $ xs) <$> extract xs) |%> (ract <=< (`asWithin` E.ask xs))
phony :: (MonadReader r m, MonadRules m) => String -> RAction r () -> m ()
phony x ract = R.ask >>= \r -> liftRules $ Development.Shake.phony x $ runRAction r ract