Data.Verbosity.Class

Type class for accessing Verbosity.

GHC Generics Example

Lets define simple data type that looks something like:

data Config = Config
    { _appVerbosity :: Verbosity
    , ...
    }
  deriving (Generic, Show, ...)

Type class HasVerbosity uses generic-lens package and DefaultSignatures language extension so that we can define instance of HasVerbosity by simply stating:

instance HasVerbosity Config

With DerivingStrategies we can rewrite the above example as:

{-# LANGUAGE DeriveAnyClass #-}
{-# LANGUAGE DeriveGeneric #-}
{-# LANGUAGE DerivingStrategies #-}

import GHC.Generics (Generic)


data Config = Config
    { _appVerbosity :: Verbosity
    , ...
    }
  deriving stock (Generic, Show, ...)
  deriving anyclass (HasVerbosity)

Hand Written Instance Example

Lets define simple data type that looks something like:

data Config = Config
    { _appVerbosity :: Verbosity
    , ...
    }
  deriving (Show, ...)

Now we can define instance of HasVerbosity by hand:

instance HasVerbosity Config where
    verbosity f c@Config{_appVerbosity = a} =
        (\b -> c{_appVerbosity = b}) <$> f a

TemplateHaskell Example

Package lens has TemplateHaskell functions that can define lenses for you:

{-# LANGUAGE TemplateHaskell #-}

import Control.Lens.TH (makeLenses)

data Config = Config
    { _appVerbosity :: Verbosity
    , ...
    }
  deriving (Show, ...)

makeLenses ''Config

Now definition of HasVerbosity instance will look like:

instance HasVerbosity Config where
    verbosity = appVerbosity   -- Lens generated by makeLenses.

HasVerbosity Type Class

class HasVerbosity s where

Minimal complete definition

Nothing

Methods

verbosity :: Functor f => (Verbosity -> f Verbosity) -> s -> f s

Lens for accessing Verbosity embedded in the type s.

Default implementaton in terms of HasType added in version 0.3.0.0.

verbosity :: (HasType Verbosity s, Functor f) => (Verbosity -> f Verbosity) -> s -> f s

Lens for accessing Verbosity embedded in the type s.

Default implementaton in terms of HasType added in version 0.3.0.0.

Instances

HasVerbosity Verbosity

Defined in Data.Verbosity.Class

Methods

verbosity :: Functor f => (Verbosity -> f Verbosity) -> Verbosity -> f Verbosity

getVerbosity :: HasVerbosity s => s -> Verbosity

Specialization of verbosity lens in to getter function.

setVerbosity :: HasVerbosity s => Verbosity -> s -> s

Specialization of verbosity lens in to setter function.

modifyVerbosity :: HasVerbosity s => (Verbosity -> Verbosity) -> s -> s

Specialization of verbosity lens in to modification function.

Verbosity Re-export

module Data.Verbosity